Question

如何将面板透明度设置为不透明度为0.我按程序设置面板，它位于视频播放器之上。代码就像这样

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click  ', AxVLCPlugin21.Click       
    Dim panelx As New Panel
    panelx.Visible = True
    panelx.Size = New Size(AxVLCPlugin21.Width, CInt(AxVLCPlugin21.Height / 2))
    panelx.BackColor = System.Drawing.Color.Transparent
    AxVLCPlugin21.Controls.Add(panelx)        
    panelx.BringToFront()
    'AddHandler panelx.DoubleClick, AddressOf panelx_click
End Sub

结果是这样的

然后我试着播放它只显示一半的视频

我使用面板的原因是暂停视频（通过透明设置面板在视频顶部），当我点击面板，因为视频不支持点击事件

更新

我把代码放在usercontrol1中

仍然给我一个错误，虽然我已在设计器中插入代码。太明确了我把代码设计师置于主设计师代码之后。我试图只在主设计器代码中放入inherit panel代码，但它只接受一个继承。

Answer 1

执行此操作的最佳方法是创建一个继承面板类的自定义控件，并使用以下代码覆盖CreateParams和OnPaintBackground：

（Zohar的道具Peled他的帖子here）

将代码替换为：

Public Class TransparentPanel
    Inherits System.Windows.Forms.Panel

    Protected Overrides ReadOnly Property CreateParams() As CreateParams
        Get
            ' Make background transparent
            Dim cp As CreateParams = MyBase.CreateParams
            cp.ExStyle = cp.ExStyle Or &H20
            Return cp
        End Get
    End Property

    Protected Overrides Sub OnPaintBackground(e As PaintEventArgs)
        ' call MyBase.OnPaintBackground(e) only if the backColor is not Color.Transparent
        If Me.BackColor <> Color.Transparent Then
            MyBase.OnPaintBackground(e)
        End If
    End Sub
End Class

并将设计师代码替换为：

<Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated()>
Partial Class TransparentPanel
    Inherits System.Windows.Forms.Panel

    'Control overrides dispose to clean up the component list.
    <System.Diagnostics.DebuggerNonUserCode()>
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub

    'Required by the Control Designer
    Private components As System.ComponentModel.IContainer

    ' NOTE: The following procedure is required by the Component Designer
    ' It can be modified using the Component Designer.  Do not modify it
    ' using the code editor.
    <System.Diagnostics.DebuggerStepThrough()>
    Private Sub InitializeComponent()
        components = New System.ComponentModel.Container()
    End Sub

End Class

您要替换的代码最初可能看起来不同，但使用此代码可确保一切正常。

注意：如果背景颜色设置为Transparent或Control，则此代码将使面板透明（这取决于控件通常实际上与透明相同。）

我试图找到用于创建和实现自定义控件的更新资源，但我无法找到维护的资源。所以这里有一些关于如何创建自定义控件的分步说明。