Question

我已经实现了一个查询，告诉数组是否已排序。我想做一个好的后置条件，它将有效地检查数组是否使用across或其他东西进行排序。

我试着这样做：

is_sorted (a: ARRAY [INTEGER]): BOOLEAN
        -- Given an array, tell if it's sorted in ascending order
    require
        array_set: a /= Void
    local
        i, j, temp: INTEGER
    do
        Result := True

        from
            i := a.lower
            j := i + 1
        invariant
            (i >= a.lower) and (i <= a.upper)
        until
            i = (a.upper) or (Result = False)
        loop
            if a[i] > a[j] then
                Result := False
            end

            i := i + 1
            j := j + 1
        variant
            a.count - i + 1
        end -- End of loop

    ensure
          -- Check if ARRAY is sorted here
    end

我试着写这样的东西：

ensure
    across a as el all (el.item <= el.forth.item) end

但这显然不起作用，因为el.forth不是查询，而是命令。

如何使across工作或我应该做些什么呢？

Answer 1

为了补充路易斯的答案，这里有一些更多的变种。首先，同一版本考虑到数组索引不必以1开头：

across a.lower |..| (a.upper - 1) as i all a [i.item] <= a [i.item + 1] end

不幸的是，当upper是最小整数值时，此版本不起作用。在这种情况下，a.upper - 1溢出并且迭代获得错误的整数间隔。解决方案是坚持原始索引范围，但条件是不比较最后一个元素：

across a.lower |..| a.upper as i until i.item >= a.upper all a [i.item] <= a [i.item + 1] end

如果从比较中排除最后一个元素，则可以直接迭代原始数组，而不是迭代一个时间间隔：

across a as i until i.target_index >= a.upper all i.item <= a [i.target_index + 1] end

或使用专用查询is_last：

across a as i until i.is_last all i.item <= a [i.target_index + 1] end

Answer 2

您可以遍历索引而不是遍历数组。这样的事情：

across 1 |..| (a.count - 1) as la_index all a.at(la_index.item) <= a.at(la_index.item + 1) end

用于确保数组已排序的有效Eiffel Postcondition

2 个答案: