添加了MUI_PAGE_INSTFILES的链接未显示

Question

我正在尝试创建一个也有“手动下载”链接的下载程序，但链接似乎没有显示。

我尝试按照this post的说明操作，但似乎无法使其正常工作。

我正在复制脚本，以防有人能指出我可能缺少的东西 - 我是NSIS脚本中的菜鸟，对不起。

!include "MUI2.nsh"
!define NAME "instfileslink"
Name "${NAME}"
OutFile "${NAME}.exe"

!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyInstFilesShow
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

Var hCtl_test_Link1

Section
    Section
    inetc::get /caption "Downloading package" "http://speedtest.ftp.otenet.gr/files/test100Mb.db" "test100Mb.db" /end   
    Pop $R0
    StrCmp $R0 "OK" 0 dlfailed  
    Quit    
dlfailed:
    DetailPrint "Download failed: $R0"
    Abort   
SectionEnd

Function fnLinkClicked
    ExecShell "open" "http://speedtest.ftp.otenet.gr/files/test100Mb.db"
FunctionEnd

Function MyInstFilesShow
    ${NSD_CreateLink} 120u 175u 100% 10u "Download manually"
    Pop $hCtl_test_Link1
    ${NSD_OnClick} $hCtl_test_Link1 fnLinkClicked
FunctionEnd

Answer 1

您不能在NSDialogs对话框之外使用NSDialogs控件（${NSD_Create*}）！

您可以使用ChangeUI / MUI_UI将控件添加到内置页面，也可以通过手动创建窗口在运行时动态添加控件。您需要使用ButtonEvent plug-in来捕获点击事件：

!include "MUI2.nsh"

!define MUI_PAGE_CUSTOMFUNCTION_SHOW MyInstFilesShow
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

!include nsDialogs.nsh ; For style defines
ShowInstDetails hide
Function MyInstFilesShow
  FindWindow $0 "#32770" "" $HWNDPARENT ; Find the inner dialog
  System::Call 'USER32::CreateWindowEx(i0, t "STATIC", t "Download manually", i${WS_CHILD}|${WS_VISIBLE}|${SS_NOTIFY}, i 100, i 200, i 300, i 50, p $0, i 0x666, p 0, p 0)p.s'
  Pop $0
  SetCtlColors $0 0000ff transparent 
  SendMessage $hwndparent ${WM_GETFONT} 0 0 $1
  SendMessage $0 ${WM_SETFONT} $1 1
  GetFunctionAddress $1 fnLinkClicked
  ButtonEvent::AddEventHandler 0x666 $1
FunctionEnd

Function fnLinkClicked
  ExecShell "open" "http://speedtest.ftp.otenet.gr/files/test100Mb.db"
FunctionEnd