Question

我一直在尝试使用BrickFTP将文件上传到Dropzone，但上传的文件不会打开，因为它包含文件内容顶部的WebKitFormBoundary。

我按照BrickFTP's documentation在Dropzone配置中将方法设为PUT。 BrickFTP使用Amazon S3，因此文件实际上传到S3。我按照他们的文档做了所有事情，除了最后一个问题，我在上传的文件内容的顶部有了这些额外的信息。

以下是负责文件上传的Coffeescript代码：

brickFTPData = {}

# As per BrickFTP docs, step 1 is 
# to get the dedicated upload url for each file by sending a  
# request to REST API to indicate intent to upload a file
getUploadUri = (file) ->
   result = ""
   $.ajax
      url      : '/a/portal-dev/get-api-keys'
      type     : 'POST'
      dataType : 'json'
      data     : { file_name: file.name }
      async    : false
      success  : (data, textStatus, jqXHR) ->
         brickFTPData[file.upload.uuid] =
            file_name   : file.name
            upload_uri  : data.upload_uri
            ref         : data.ref
         result = data.upload_uri
   return result

# 3rd step is to notify the REST API that the file upload is complete.
finishUpload = (file) ->
   $.ajax
      url      : '/a/portal-dev/upload-done'
      type     : 'POST'
      dataType : 'json'
      data     :
         ref         : brickFTPData[file.upload.uuid].ref
         file_name   : brickFTPData[file.upload.uuid].file_name
      success  : (data) ->
         delete brickFTPData[file.upload.uuid]
         console.log data.status

# 2nd step is to upload the file
sampleQuoteDropzone = new Dropzone "#sampleQuoteDropzone",
   url            : '/demo'
   method         : 'PUT'
   headers        : {"Content-Type": "application/octet-stream"}
   success        : (file, request) ->
      finishUpload(file)

sampleQuoteDropzone.on 'processing', (file) ->
   upload_uri = getUploadUri(file)
   sampleQuoteDropzone.options.url = upload_uri

使用上面的代码上传工作正常但是当我将上传的文件打开到文本编辑器时，它会从以下代码开始：

------WebKitFormBoundaryw4bIakMBbkp7ES2E
Content-Disposition: form-data; name="file"; filename="IMG_5652.jpg"
Content-Type: image/jpeg

如果删除这些行并保存文件，它将起作用。

但是在使用Dropzone外部的常规ajax调用上传文件时，看不到此问题。以下是工作代码：

$.ajax
     url: data.upload_uri
     type: 'PUT'
     contentType: 'application/octet-stream'
     data: file
     processData: false
     success: (response) ->
        finishUpload(file, data)

有人可以建议如何解决这个问题吗？

Answer 1

我用以下代码解决了这个问题：

sampleQuoteDropzone.on 'sending', (data, xhr, formData) ->
   _send = xhr.send
   xhr.send = ->
      _send.call(xhr, data)

实际上找到了此解决方案here。我在这里发布这个问题之前看到了这个，但不确定这是否是正确的问题/解决方案。我联系了BrickFTP，他们很快就回答说这个解决方案可能对我有用，是的，肯定会。

使用Dropzone将文件上传到BrickFTP

1 个答案: