Question

以下是XML示例：

<root>
    <persons>
        <person gender="female">X</person>
        <person gender="female">Y</person>
        <person gender="male">Z</person>
    </persons>
</root>

我希望通过使用GPath获取具有gender="male"的元素计数。

我有以下代码：

def xml =
'''
    <root>
        <persons>
            <person gender="female">X</person>
            <person gender="female">Y</person>
            <person gender="male">Z</person>
        </persons>
    </root>    
'''

def slurper = new XmlSlurper()
def parsedText = slurper.parseText(xml)
def locator = 'persons.person[@gender="male"]'

def elements = Eval.x(parsedText, "x.${locator}")

println elements.size()

它给了我错误：

org.codehaus.groovy.control.MultipleCompilationErrorsException: startup failed:
Script1.groovy: 1: unexpected token: = @ line 1, column 25.
   x.persons.person[@gender="male"]
                           ^

1 error

该代码仅用于解决问题的示例。在实际情况中，我有一个实用方法，它接受XML和GPath，如果给定的GPath可以找到任何元素，则返回。

更新：1

以下是实际的实用程序方法，它将xml和locator（GPath）作为args并检查是否有任何元素的路径与提供的定位符匹配。

public static void verifyElementExists(String xml, String locator) throws NoElementFoundException {
    def slurper = new XmlSlurper()
    def parsedText = slurper.parseText(xml)
    def elements = Eval.x(parsedText, "x.${locator}")

    if(elements.size() == 0) {
        throw new NoElementFoundException()
    }
}

Answer 1

不确定您要尝试的确切用例。

如果您需要一种方法，如果某个元素或提供的GPath可用，则可以返回，可以通过以下方式实现：

解决方案确实没有太大变化。

而不是字符串作为定位器，用户需要传递与Closure相同的内容，而不使用Eval。

//Method to find if element exists.
static def isElementExists (String xmlStr, Closure closure){
    def xml = new XmlSlurper().parseText(xmlStr)
    def elements = closure(xml)
    elements.size() ? true : false    
}

def xmlString = '''<root>
    <persons>
        <person gender="female">X</person>
        <person gender="female">Y</person>
        <person gender="male">Z</person>
    </persons>
</root>'''

//Call to the above method, use either of the way to make a call; both are same
//In the below example, the same string used as locator is being passed as Closre
println isElementExists(xmlString) {x -> x.'**'.findAll { it.name()=='person' && it.@gender == 'male' } }

或

println isElementExists(xmlString, {x -> x.'**'.findAll { it.name()=='person' && it.@gender == 'male' } } )

如果您只想检查person元素是否存在，那么您可以按如下方式使用它：

println isElementExists(xmlString) {x -> x.persons.person }

您可以快速在线试用 demo

编辑：提高可读性或简化。

你甚至可以这样做。当然，最后一个语句和下面的语句结果相同。

def locator = {x -> x.persons.person }
println isElementExists(xmlString, locator)

Answer 2

认为你需要

def locator = "persons.person.findAll { it.@gender == 'male' }"

如果可能的话，我会避免这种情况，使用Eval并不是一条安全的行走路径

使用动态GPath表达式按属性值查找XML元素

更新：1

2 个答案: