Question

如何在ALV网格中显示内联声明的数据类型？

例如：

SELECT *
INTO TABLE @DATA(lt_result)
FROM table.

如何在ALV网格中显示lt_result？

Answer 1

这是一个基本的例子：

DATA: alv TYPE REF TO cl_salv_table.   

SELECT *
INTO TABLE @DATA(lt_result)
FROM table.

cl_salv_table=>factory( IMPORTING r_salv_table = alv
                        CHANGING  t_table      = lt_result ).

alv->display( ).

您可以在SALV_OM_OBJECTS包中找到使用SALV对象模型的其他示例。

这是一种比使用'REUSE_ALV_GRID_DISPLAY'更现代的方法，您不需要定义字段目录。

Answer 2

无论你如何创建lt_result，你都必须做同样的事情。您的示例中的select *将导致lt_result等于DATA lt_result type table of tablename

在这种情况下，您可以发送结构的名称。但这只有在SE11中定义结构类型时才有效，即如果你做select *没有任何连接或别名。

否则，您必须在字段目录中创建并发送您希望显示的lt_result中的所有字段。

示例：

SELECT * FROM mara
UP TO 10 ROWS
INTO TABLE @DATA(lt_mara).

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  EXPORTING
    i_callback_program = sy-repid
    i_structure_name   = 'MARA'
*    it_fieldcat  => use this if i_structure_name is not sufficient
  TABLES
    t_outtab           = lt_mara
  EXCEPTIONS
    OTHERS             = 1.

如果您使用cl_gui_alv_grid，则同样适用。

编辑：您可以像这样动态填写字段目录：

DATA:
  lo_t_struct TYPE REF TO cl_abap_tabledescr,
  lo_struct   TYPE REF TO cl_abap_structdescr.

lo_t_struct ?= cl_abap_tabledescr=>describe_by_data( lt_result ).
lo_struct ?= lo_t_struct->get_table_line_type( ).

LOOP AT lo_struct->components ASSIGNING FIELD-SYMBOL(<comp>).
  "Fill a range-table with <comp>-name
ENDLOOP.

使用范围表从表dd04t获取字段描述。

然后再次在lo_struct->components循环，并使用字段名称和描述填充字段目录。在这里，您还可以为任何给定字段添加特殊逻辑。

ALV网格用于在线声明

2 个答案: