Question

我试图找出以下XML的XSLT（CSV输出）我想对孙子节点进行排序，即对Month节点进行排序，并选择具有最高月值的集合的Sales_Program-ID节点值。

XML

<Root>
    <Level1>
        <EMPLID>123</EMPLID>
        <Program>
            <Sales_Program Name="XYZ">
                <ID1>ab</ID1>
            </Sales_Program>
            <Start_Date>Jan1st</Start_Date>
            **<Month>1</Month>**
        </Program>
        <Program>
            <Sales_Program Name="ABC">
                <ID1>cd</ID1>
            </Sales_Program>
        <Start_Date>Feb1</Start_Date>
        **<Month>2</Month>**
        </Program>
    </Level1>
    <Level1>
        <EMPLID>456</EMPLID>
        <Program>
            <Sales_Program Name="XYZ">
                <ID1>ab</ID1>
            </Sales_Program>
            <Start_Date>Jan1st</Start_Date>
            <Month>1</Month>
        </Program>
    </Level1>
</Root>

预期产出：

123,ab,Feb1,2 - (From first Level1 Node)
456,cd,Jan1st,1  (From second Level1 Node)

Answer 1

所以你想要Program子元素对Month元素进行排序，在XSLT 3中支持高阶sort函数，你可以用

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    exclude-result-prefixes="xs math"
    version="3.0">

    <xsl:output method="text"/>

    <xsl:template match="/">
        <xsl:apply-templates select="Root/Level1"/>
    </xsl:template>

    <xsl:template match="Level1">
        <xsl:value-of select="EMPLID, sort(Program, (), function($p) { -$p/Month/xs:integer(.) })[1]/(Sales_Program/ID1, Start_Date, Month)" separator=","/>
        <xsl:text>&#10;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

在XSLT 2中，您需要使用xsl:perform-sort：

在您自己的函数中实现排序

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="xs mf"
    version="2.0">

    <xsl:output method="text"/>

    <xsl:function name="mf:sort">
        <xsl:param name="programs" as="element(Program)*"/>
        <xsl:perform-sort select="$programs">
            <xsl:sort select="xs:integer(Month)" order="descending"/>
        </xsl:perform-sort>
    </xsl:function>

    <xsl:template match="/">
        <xsl:apply-templates select="Root/Level1"/>
    </xsl:template>

    <xsl:template match="Level1">
        <xsl:value-of select="EMPLID, mf:sort(Program)[1]/(Sales_Program/ID1, Start_Date, Month)" separator=","/>
        <xsl:text>&#10;</xsl:text>
    </xsl:template>

</xsl:stylesheet>

XSLT对孙子节点进行排序并选择另一个孙子的值

1 个答案: