Question

我喜欢Haskell类型同义词的概念，因为它们允许区分共享底层表示的抽象数据类型。不幸的是，当我编写像

这样的程序时

data Vector a = Vec a a

-- Some definitions here about (+) and (*) for Vector ...

type Position = Vector Float
type Velocity = Vector Float
type Time = Float

step :: Position -> Velocity -> Time -> Position
step p v dt = p + v*dt

p :: Position
p = Vec 0.0 0.0

v :: Velocity
v = Vec 1.0 1.0

p' = step v p 0.01

这是完全有效的Haskell代码，尽管v和p位于错误的位置。我想加强类型同义词之间的区别，这样它们仍然可以共享底层表示，但在函数应用程序中不会被接受。这可能吗？

Answer 1

newtype很可能是你想要的，或者无论如何，我们得到的最好的。与type类似，它为现有类型定义新名称，并且运行时表示将是相同的。与type不同（但与data类似），在类型检查期间它们被认为是不同的，并且有一个新的数据构造函数。

所以你可能有以下代码：

newtype Position = Position (Vector Float)
p :: Position
p = Position (Vec 0 0)

Answer 2

您可以将Vector设为phantom type，如下所示：

data Vector t a = Vec a a

data Pos
data Vel

type Position = Vector Pos Float
type Velocity = Vector Vel Float

现在，您可以像往常一样定义Position和Velocity的实例：

p :: Position
p = Vec 0.0 0.0

v :: Velocity
v = Vec 1.0 1.0

但是，它不允许您互换使用它们：

type Time = Float

step :: Position -> Velocity -> Time -> Position
step p v dt = p + v*dt -- you might have to change this definition

p' = step v p 0.01 -- won't compile

您还可以使用DataKinds和KindSignatures

来更精确地制作内容

{-# LANGUAGE DataKinds #-}
{-# LANGUAGE KindSignatures #-}

data VectorType = Pos | Vel

data Vector (t :: VectorType) a = Vec a a

type Position = Vector Pos Float
type Velocity = Vector Vel Float

希望有所帮助。

让Haskell区分类型同义词

2 个答案: