Question

match (s:Product {type:'Phone'})-[r]->(o:Attributes) where exists(o.color) return s.name, o.color

此查询返回每个产品名称及其“颜色”属性。在这种情况下，将反复显示许多重复的产品和颜色。相反，我想要返回所有“颜色”而不重复。例如，在结果集中，可能有100个产品，但只有5种不同的颜色。我想只返回5种不同的颜色。

如何实现？是否仍然可以将s.name和独特颜色一起返回？如果没有，只需返回独特的颜色即可。

编辑：这似乎有效：

return collect(distinct(o.color)) limit 5

它返回唯一的“颜色”，但“限制5”不起作用。它返回所有独特的颜色。

Answer 1

LIMIT子句限制返回记录的数量。您的第二个查询返回单个记录（由所有不同颜色的单个集合组成）。 LIMIT子句对该集合中的项目数没有影响。

最多获得5种与＆＃34; Phone＆＃34;相关的独特颜色。 Product（s），你可以这样做：

MATCH (:Product {type:'Phone'})-->(o:Attributes)
WHERE EXISTS(o.color)
RETURN DISTINCT o.color AS color
LIMIT 5;

此查询将为每种唯一颜色返回一条记录。要获得所有与＆＃34; Phone＆＃34;相关的独特颜色。 Product（s），只需删除LIMIT条款。

如果您想获得最多5种独特颜色的单一集合，您可以这样做：

MATCH (:Product {type:'Phone'})-->(o:Attributes)
WHERE EXISTS(o.color)
WITH DISTINCT o.color AS color
LIMIT 5
RETURN COLLECT(color) AS colors;

[UPDATE]

按频率降序获得前5种颜色：

MATCH (:Product {type:'Phone'})-->(o:Attributes)
WHERE EXISTS(o.color)
WITH o.color AS color, COUNT(*) AS colorCount
ORDER BY colorCount DESC
RETURN color
LIMIT 5;

请注意，不需要DISTINCT，因为WITH子句使用aggregating function（COUNT）color作为分组键。这会导致WITH子句的输出为具有不同color值的记录。

如何编写此累加器查询？

1 个答案: