Question

我试图通过实现这段代码来使用第一类模块：

module Component =
  struct

    type t_data = ..

    module type S =
      sig
        type t
        val create : t -> t_data
      end

    module Make (C: sig type t end) =
      struct
        type t = C.t
        type t_data += T of C.t
        let create data = T data
      end

  end

let create m data =
  let module M = (val m : Component.S) in M.create data

(*  The type constructor M.t would escape its scope *)

我也会尝试这个替代方案，但我不知道如何在模块S中添加扩展类型t_data：

let create' m data =
  let module M = (val m : Component.S) in M.T data
(* Unbound constructor M.T *)

我正在使用bucklescript，谢谢！

Answer 1

你只需要一些额外的注释来说服typechecker：

let create (type t0) (m : (module Component.S with type t = t0)) data =
  let module M = (val m) in M.create data

可以缩短为：

let create (type t0) (module M : Component.S with type t = t0) data =
  M.create data

(type t)注释引入了本地抽象数据类型。在函数外部，此类型转换为通用类型变量，因此给出类型：

val create : (module Component.S with type t = 'a) -> 'a -> Component.t_data

您可以像任何其他类型一样使用本地抽象类型，特别是您也可以将它放在本地定义的模块中：

let inject (type t0) data =
  let module M0 = struct type t = t0 end in
  let module M = Component.Make(M0) in
  M.create data
val make : 'a -> Component.t_data

Ocaml一流模块和扩展变体

1 个答案: