Question

我有这个过程交换Word变量的字节（低/高）（它与System.Swap函数的作用相同）。当编译器优化为OFF时，该过程有效，但当它处于ON状态时，该过程无效。有人可以帮我吗？

procedure SwapWord(VAR TwoBytes: word);   
asm
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
end;

Answer 1

如果不保存/恢复，则不能在ASM代码中使用EBX寄存器。您的代码的更正版本是

procedure SwapWord_Working(VAR TwoBytes: word);   
asm
  PUSH EBX     // save EBX
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
  POP EBX     // restore EBX
end;

Answer 2

最快：

function ReverseWord(w: word): word;
asm
   {$IFDEF CPUX64}
   mov rax, rcx
   {$ENDIF}
   xchg   al, ah
end;

如果你想要反转DWORD：

function ReverseDWord(dw: cardinal): cardinal;
asm
  {$IFDEF CPUX64}
  mov rax, rcx
  {$ENDIF}
  bswap eax
end;

Answer 3

我有点惊讶没有人提到absolute“hack”已经存在了十多年但却没有得到太多的关注......反正这里是我的两分钱

function SwapWordBytes(const Value: Word): Word;
var
  // shares memory with Value parameter
  LMemValue: array[0..1] of Byte absolute Value;
  // shares memory with Result
  LMemResult: array[0..1] of Byte absolute Result;
begin
  LMemResult[0] := LMemValue[1];
  LMemResult[1] := LMemValue[0];
end;

Answer 4

您是否考虑过使用编译器的Swap函数？

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $1234;
  a := Swap(a);
  Caption := IntToHex(a, 4)
end;

如果没有，您不需要ASM（并且ASM可能无法在64位Delphi中使用）。你可以做到

procedure MySwap(var a: word);
var
  tmp: byte;
begin
  tmp := PByte(@a)^;
  PByte(@a)^ := PByte(NativeUInt(@a) + sizeof(byte))^;
  PByte(NativeUInt(@a) + sizeof(byte))^ := tmp;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $123456;
  MySwap(a);
  Caption := IntToHex(a, 4)
end;

当然，这个主题有“一百万”的变化。

procedure MySwap(var a: word);
var
  tmp: byte;
type
  PWordRec = ^TWordRec;
  TWordRec = packed record
    byte1, byte2: byte;
  end;
begin
  with PWordRec(@a)^ do
  begin
    tmp := byte1;
    byte1 := byte2;
    byte2 := tmp;
  end;
end;

，非常简短，

procedure MySwap(var a: word);
begin
  a := word(a shl 8) + byte(a shr 8);
end;

或

procedure MySwap(var a: word);
begin
  a := lo(a) shl 8 + hi(a);
end;

Answer 5

尽管Serg的答案肯定是正确的，正如对Serg的答案的评论所指出的那样，但效率并不高。最快的显然是Gabr的答案中提供的代码，但由于您明确需要一个过程而不是一个函数，以下将是Serg例程的首选版本：

procedure SwapWord_Working2 (VAR TwoBytes: word);
asm
  mov dx, [TwoBytes]  ;//[TwoBytes] = [eax] on x86 *[Note1]
  xchg dl, dh
  mov [TwoBytes], dx
end;

[注1：] Serg的函数版本很可能不适用于即将推出的x64 Delphi编译器。假设Embarcadero坚持使用Win64调用约定（其中@TwoBytes将通过RCX传递）的计划（由Allen Bauer提及），此答案中提供的版本仍应在x64上运行。

交换Word变量的字节（低/高）的过程

5 个答案: