Question

我正在尝试一个应该创建表的xsl-fo示例，但是当我运行它时，它并排显示了数据，没有表行或单元格。如何使其正确显示？

我在.xml文件中有一个样式表标签，因此当我右键单击它并选择“使用Internet Explorer打开”时，它应该与.xslt文件一起翻译。

预期输出，两个输出将在单独的行中，
FO第一办公室
FO第二办公室

我的代码

personnel_roster2.xslt

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
    xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:template match='/rows'>
        <fo:root>

          <fo:layout-master-set>
            <fo:simple-page-master master-name="hello"
                        page-height="11in"  page-width="8.5in" margin-top="1in" 
                        margin-bottom="1in" margin-left="0in" margin-right="1in">
              <fo:region-body margin-top="1in" margin-bottom=".5in"/>
            </fo:simple-page-master>
          </fo:layout-master-set>

            <fo:page-sequence master-reference="hello">
                <fo:flow flow-name="xsl-region-body">
                    <fo:table>
                        <xsl:for-each select="row">
                            <fo:table-row>
                                <fo:table-cell>
                                    <fo:block font-weight="bold"><xsl:value-of select="@Office"/></fo:block>
                                </fo:table-cell>
                                <fo:table-cell>
                                    <fo:block font-weight="bold"><xsl:value-of select="@OfficeTitle"/></fo:block>
                                </fo:table-cell>
                            </fo:table-row>
                        </xsl:for-each>
                    </fo:table>
                </fo:flow>
            </fo:page-sequence>
        </fo:root>
    </xsl:template>
</xsl:stylesheet>

personnel_roster2.xml

<?xml version = "1.0"?>
<?xml-stylesheet type = "text/xsl" href = "personnel_roster2.xslt"?> 
<rows appMode="DEV" dateGenerated="">
    <row OfficeID="32" OfficeOutputOrder="1" Office="FO" OfficeTitle="First Office" RoomFaxID="88" RoomFaxNumber="" RoomNumberID="123">
        <personnel>
            <person PersonnelID="3870" Name="The Boss" PositionRoomNumberID="31" phone="555-647-5770" PAETitle="" PositionEmployeeTypeID="C" PositionOutputOrder="1" />
        </personnel>
        <officeFaxes>
             <fax RoomNumberID="123" RoomFaxNumber="" OfficeID="32" />
        </officeFaxes>
    </row>
    <row OfficeID="33" OfficeOutputOrder="1" Office="FO" OfficeTitle="Second Office" RoomFaxID="88" RoomFaxNumber="" RoomNumberID="123">
        <personnel>
            <person PersonnelID="3870" Name="The Boss" PositionRoomNumberID="31" phone="555-647-5770" PAETitle="" PositionEmployeeTypeID="C" PositionOutputOrder="1" />
        </personnel>
        <officeFaxes>
             <fax RoomNumberID="123" RoomFaxNumber="" OfficeID="33" />
        </officeFaxes>
    </row>
</rows>

Answer 1

我不知道原生支持XSL-FO的现代浏览器。

因此，您可以直接将其转换为HTML，或者将XSL-FO输出转换为具有不同XSLT的HTML。

第二种方法的示例，再次转换输出，是：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output method="html" indent="yes"/>

    <xsl:template match="/fo:root/fo:page-sequence/fo:flow">
        <html>
            <body>
                <xsl:for-each select="fo:table">
                    <table border="1">
                        <xsl:for-each select="fo:table-row">
                            <tr>
                                <xsl:for-each select="fo:table-cell">
                                    <td style="font-weight:{fo:block/@font-weight};">
                                        <xsl:value-of select="fo:block" />
                                    </td>
                                </xsl:for-each>
                            </tr>
                        </xsl:for-each>
                    </table>
                </xsl:for-each>
            </body>
        </html>
     </xsl:template>    

</xsl:stylesheet>

这会将第一个XSLT的输出转换为可以在浏览器中显示的HTML文件。

Answer 2

您未声明有关XSL FO处理器的任何信息。 XSL FO是应用程序解释并创建输出的标记语言。这与HTML相同...对于HTML，浏览器会解释HTML标记和CSS样式，并在浏览器中为您提供“组合”视图。

要对XSL FO执行相同操作，请使用一些XSL FO处理器，该处理器解释XSL FO标记并创建输出（可以是PDF或Postscript或许多其他组合输出，例如AFP，PCL，XPS等）

要从XSL FO获得真实的格式化输出，您需要一个XSL FO处理器。没有浏览器会这样做。这是开源世界或RenderX XEP或AntennaHouse等商业应用程序中的Apache FOP。

如何使xsl-fo表格显示为表格？

2 个答案: