coefplot：将回归名称放在y轴上

Question

以下代码将生成系数图：

sysuse auto, clear
regress price mpg trunk length turn if foreign==0
estimates store D
regress price mpg trunk length turn if foreign==1
estimates store F
coefplot D F, drop(_cons) xline(0)

但是，我想将每个存储的回归结果集的自定义名称放在y-axis上：

我尝试过各种有关比例和标签的事情，例如xrescale，但失败了。

---

编辑：

我不是要重复Domestic和Foreign。我只想保留trunk。 不需要所有其他系数。因此Domestic和Foreign只会出现一次。

Answer 1

我认为这是一个糟糕的主意。如果您继续重复Domestic/Foreign，那么读者将无法知道哪个对对应于每个变量。

这是一种更好的方法：

sysuse auto, clear
estimates clear 

regress price mpg trunk length turn if foreign==0
estimates store D

regress price mpg trunk length turn if foreign==1
estimates store F

coefplot (D, asequation(Domestic) \ F, asequation(Foreign)), drop(_cons) xline(0) 

或者：

coefplot (D, asequation \ F, asequation), drop(_cons) xline(0) ///
eqlabels("Domestic" "Foreign", asheadings)

---

编辑：

实现以下目标的唯一方法是使用以下技巧：

coefplot D F, drop(_cons mpg length turn) ///
coeflabels(trunk = `""Domestic -" " " " " " " " " " " " " " " "Foreign -""') ///
ylabel(, notick labgap(0)) xline(0) legend(off)

显然，您将不得不针对不同的用例进行调整。