Question

我需要使用bat文件将源文件复制到目标文件夹。

我创建了这个：

@echo off

set source="D:\Folder1\file.dll"
set destination="D:\Test\TestCopy*\Test\"
xcopy /s /y %source%  %destination%
pause

我的目标路径是TestCopy.2.5.3.6。这个数字可以改变。因此，指定TestCopy*不起作用。指定TestCopy.*.*.*.*也不起作用。

我该如何解决？

Answer 1

这不是使用xcopy的方式：它无法将目录结构/文件复制到某些子文件夹中存在的文件夹中，例如将文件random.ext复制到C:\folder1\test，C:\folder2\test等。

此外，无需使用xcopy复制文件。请改用copy

要实现此目的，请使用：

@echo off

pushd "D:\Test"
set source="D:\Folder1\file.dll"

for /F "delims= eol=" %%A IN ('dir /B /AD "D:\Test\TestCopy*"') do (
    copy %source% "%%~fA\Test\"
)
popd

或者更好的单行for /F：

@echo off

pushd "D:\Test"
set source="D:\Folder1\file.dll"

for /F "delims= eol=" %%A IN ('dir /B /AD "D:\Test\TestCopy*"') do copy %source% "%%~fA\Test\"
popd

Answer 2

这是针对您有多个TestCopy*子文件夹的情况：

::It's better to comment out @echo off when you are testing the batch file
::@echo off
::Moved the open quote's position, so the source variable won't have quotes inside.
set "source=D:\Folder1\file.dll"
for /F "delims=" %%i IN ('dir /ad /b "D:\Test\TestCopy*"') do call :fcopy "%%i"
::Comment or remove pause when it's okay.
pause
goto :eof

:fcopy
if not exist "D:\Test\%1\Test\" goto :eof
xcopy "%source%" "D:\Test\%1\Test\"

使用了子过程:fcopy，将每个TestCopy*子文件夹名称传递给它。
所有::起始行都是注释行。它们没有执行。

我认为在使用路径时引用每个路径变量是一个好习惯，但不要在变量中包括引号本身，这就是为什么我将引号移到set source行中。

Xcopy目录模式匹配

2 个答案: