Question

我用Google搜索了data-reactid，在大多数情况下，它似乎不适用于VBA。

但是我仍然认为可能有答案。我想在“ 经营活动产生的现金流量总额”中获得数字

https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA

Sub YFinance()

    Dim XMLReq As New MSXML2.XMLHTTP60
    Dim HTMLDoc As New MSHTML.HTMLDocument
    Dim i As Integer
    Dim strUrl As String



    XMLReq.Open "GET", "https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA", False
    XMLReq.send

    If XMLReq.Status <> 200 Then
        MsgBox "Error!"
        Exit Sub
    End If

    HTMLDoc.body.innerHTML = XMLReq.responseText

    Set XMLReq = Nothing

    MsgBox HTMLDoc.getElementsById("Bdbw(0px)! H(36px)")(0).innerText






End Sub

Answer 1

getElementById返回一个节点，因此您不会像以前那样索引它。没有方法getElementsById，因此应该失败并显示错误。

您可以使用该类并转义特殊字符并索引到返回的集合中

MsgBox HTMLDoc.querySelectorAll(".Bdbw\(0px\)\!")(1).innerText

或将复合类传递给getElementsByClassName：

MsgBox HTMLDoc.getElementsByClassName("Bdbw(0px)! H(36px)")(1).innerText

属性（不是id）data-reactid在页面和输出之间可能会有所不同（在这种情况下-输出中的行的id是113。在这种情况下，使用表和行索引可能会更安全

MsgBox HTMLDoc.getElementsByTagName("table")(2).getElementsByTagName("tr")(9).innerText

如果您想要该行的每一列：

Dim td As Object, tds As Object
Set tds = HTMLDoc.getElementsByTagName("table")(2).getElementsByTagName("tr")(9).getElementsByTagName("td")
For Each td In tds
    Debug.Print td.innerText
Next

或

Dim td As Object, tds As Object
Set tds = HTMLDoc.getElementsByClassName("Bdbw(0px)! H(36px)")(1).getElementsByTagName("td")
For Each td In tds
    Debug.Print td.innerText
Next

正如我所说，数据反应堆可以伸缩，但是如果您想知道如何为此应用属性选择器，请参阅：

MsgBox HTMLDoc.querySelector("tr[data-reactid='113']").innerText

Answer 2

您可以尝试以下操作以确保安全。 for loop一旦获得所需的节点，它将为您获取所需的内容并退出循环。

Sub FetchFinanceInfo()
    Dim XMLReq As New XMLHTTP60, HTMLDoc As New HTMLDocument
    Dim post As Object, I&

    XMLReq.Open "GET", "https://finance.yahoo.com/quote/BABA/cash-flow?p=BABA", False
    XMLReq.send
    HTMLDoc.body.innerHTML = XMLReq.responseText

    For Each post In HTMLDoc.getElementsByTagName("span")
        If InStr(post.innerText, "From Operating Activities") > 0 Then
            With post.ParentNode.ParentNode.getElementsByTagName("td")
                For I = 1 To .Length - 1
                    Debug.Print .Item(I).innerText
                Next I
            End With
            Exit For
        End If
    Next post
End Sub

VBA数据反应式显示Yahoo Finance的财务编号

2 个答案: