Question

我有多个出现节点，需要使用XSLT转换在输出中生成。你能帮我这个忙吗？

下面的XSLT代码仅生成一个节点。您能否用下面的XSLT代码帮助我，如何在输入XML中生成多个节点元素

输入XML

    <?xml version="1.0" encoding="UTF-8" ?> 
    <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" >
    <soapenv:Body>
    <ns1:getGenResponse soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/" 
    <ns1:getGenReturn xsi:type="soapenc:Array" soapenc:arrayType="xsd:anyType[2]" xmlns:soapenc="http://schemas.xmlsoap.org/soap/encoding/">
    </ns1:getGenReturn>
    </ns1:getGenResponse>
    <multiRef id="id0" soapenc:root="0" soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/" xsi:type="ns2:Gen" xmlns:soapenc=http://schemas.xmlsoap.org/soap/encoding/>
        <name xsi:type="xsd:string">ULM</name> 
         <mail xsi:type="xsd:string">ulm@gmail.com</mail> 
    </multiRef>
    <multiRef id="id1" soapenc:root="0" soapenv:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/" xsi:type="ns3:Gen" " xmlns:soapenc="http://schemas.xmlsoap.org/soap/encoding/">
         <name xsi:type="xsd:string">ABC</name> 
         <mail xsi:type="xsd:string">abc@gmail.com</mail> 
    </multiRef>
    </soapenv:Body>
    </soapenv:Envelope>

用于此转换的XSLT代码

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" x
 xmlns:response="http://tempuri.org/" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- Output -->
<xsl:output method="xml" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
<xsl:if test="//soap:Body/multiRef">
<xsl:element name="getGenResponse">
  <xsl:element name="getGenReturn">
                               <xsl:element name="name"><xsl:value-of select="//name"/></xsl:element>

                               <xsl:element name="mail"><xsl:value-of select="//mail"/></xsl:element>
  </xsl:element>
</xsl:element>
</xsl:if>
</xsl:template>

   <!-- 'Copy ' node -->
<xsl:template match="@* | node()">
   <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
   </xsl:copy>
</xsl:template>
</xsl:stylesheet>

XSLT上方的输出

<?xml version="1.0" encoding="UTF-8"?>
<getGenResponse>
   <getGenReturn>
      <name> ULM </name>
      <mail>ulm@gmail.com<mail>
   </getGenReturn>
/getGenResponse>

预期输出

<?xml version="1.0" encoding="UTF-8"?>
<getGenResponse>
   <getGenReturn>
      <name> ULM </name>
      <mail>ulm@gmail.com<mail>
   </getGenReturn>
  <getGenReturn>
      <name>ABC</name>
      <mail>abc@gmail.com<mail>
  </getGenReturn>
/getGenResponse>

Answer 1

目前，您要做的只是测试一个multiRef元素是否存在，并仅输出一个新的getGenReturn元素。

您真正需要做的就是将xsl:if替换为xsl:for-each以选择所有元素，然后每个元素都会得到一个getGenReturn。并更改xsl:value-of以使用相对路径

<xsl:template match="/">
  <xsl:element name="getGenResponse">
    <xsl:for-each select="//soap:Body/multiRef">
      <xsl:element name="getGenReturn">
        <xsl:element name="name"><xsl:value-of select="name"/></xsl:element>
        <xsl:element name="mail"><xsl:value-of select="mail"/></xsl:element>
      </xsl:element>
    </xsl:for-each>
  </xsl:element>
</xsl:template>

或更妙的是，执行此操作，因为如果您使用的是静态名称，此处实际上并不需要xsl:element

<xsl:template match="/">
  <getGenResponse>
    <xsl:for-each select="//soap:Body/multiRef">
      <getGenReturn>
        <name><xsl:value-of select="name"/></name>
        <mail><xsl:value-of select="mail"/></mail>
      </getGenReturn>
    </xsl:for-each>
  </getGenResponse>
</xsl:template>

注意，在这种情况下，您实际上不需要身份模板。试试这个XSLT：

<xsl:stylesheet version="1.0" xmlns:response="http://tempuri.org/" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="soap response">

    <!-- Output -->
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
      <getGenResponse>
        <xsl:for-each select="//soap:Body/multiRef">
          <getGenReturn>
            <name><xsl:value-of select="name"/></name>
            <mail><xsl:value-of select="mail"/></mail>
          </getGenReturn>
        </xsl:for-each>
      </getGenResponse>
    </xsl:template>
</xsl:stylesheet>

Answer 2

<xsl:stylesheet version="1.0" xmlns:response="http://tempuri.org/" 
xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="soap response">

    <!-- Output -->
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">

        <getGenResponse>
        <xsl:for-each select="//soap:Body/multiRef">
          <getGenReturn>
            <name><xsl:value-of select="name"/></name>
            <mail><xsl:value-of select="mail"/></mail>
          </getGenReturn>
         </xsl:for-each>
        </getGenResponse>

    </xsl:template>
</xsl:stylesheet>

具有多个节点的XSLT转换

2 个答案: