Delphi TList的记录

时间：2011-04-26 22:46:48

标签： delphi record tlist

我需要存储一个临时记录列表，并且认为TList是一个很好的方法吗？但是，我不确定如何使用TList进行此操作并且想知道这是否是最好的，并且如果有人有任何示例如何执行此操作？

8 个答案:

答案 0 :(得分：28)

最简单的方法是创建自己的TList后代。这是一个快速示例控制台应用程序，用于演示：

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes;

type
  PMyRec=^TMyRec;
  TMyRec=record
    Value: Integer;
    AByte: Byte;
  end;

  TMyRecList=class(TList)
  private
    function Get(Index: Integer): PMyRec;
  public
    destructor Destroy; override;
    function Add(Value: PMyRec): Integer;
    property Items[Index: Integer]: PMyRec read Get; default;
  end;

{ TMyRecList }

function TMyRecList.Add(Value: PMyRec): Integer;
begin
  Result := inherited Add(Value);
end;

destructor TMyRecList.Destroy;
var
  i: Integer;
begin
  for i := 0 to Count - 1 do
    FreeMem(Items[i]);
  inherited;
end;

function TMyRecList.Get(Index: Integer): PMyRec;
begin
  Result := PMyRec(inherited Get(Index));
end;

var
  MyRecList: TMyRecList;
  MyRec: PMyRec;
  tmp: Integer;
begin
  MyRecList := TMyRecList.Create;
  for tmp := 0 to 9 do
  begin
    GetMem(MyRec, SizeOf(TMyRec));
    MyRec.Value := tmp;
    MyRec.AByte := Byte(tmp);
    MyRecList.Add(MyRec);
  end;

  for tmp := 0 to MyRecList.Count - 1 do
    Writeln('Value: ', MyRecList[tmp].Value, ' AByte: ', MyRecList[tmp].AByte);
  WriteLn('  Press Enter to free the list');
  ReadLn;
  MyRecList.Free;
end.

这消除了以下几点：

  • 它处理释放内存。
  • 您不必为了使用它而对所有内容进行类型转换。

正如雷米和沃伦所说，这是一个更多的工作，因为你必须在添加新记录时分配内存。

答案 1 :(得分：18)

首先，如果您想将经典TList与Records结合使用，则需要：

  1. 在堆上分配您的记录，而不是在堆栈上。像雷米那样使用GetMem。
  2. 获取记录的地址并将其添加到TList。
  3. 从列表中删除项目并使用它时，请取消引用它：
  4. 记得随后自由清理。

    5. 将列表与记录结合起来需要大量的“指针和堆管理”工作，这种技术只能在专家的能力范围内。

    你所要求的替代品仍然使用名为“TList”的东西，包括使用generics.collections样式的TList，记录类型，这将具有TList的所有好处，但需要你基本上做很多事情整个记录副本以获取数据。

    最常用的德尔福方法可以做到你要求的：

    1. 使用带有类类型的TList或TObjectList而不是记录。通常，在这种情况下，您最终会继承TList或TObjectList。

    2. 使用动态的记录类型数组，但请注意，对数组类型进行排序更加困难，并且在运行时扩展数组类型并不像使用TList那样快速。

    3. 对您的班级使用generics.Collections TList。这使您可以在每次要使用具有不同类的列表时避免继承TList或TObjectList。

      4. 显示动态数组的代码示例：

       TMyRec = record
    ///
 end;

 TMyRecArray = array of TMyRec;

 procedure Demo;
 var
    myRecArray:TMyRecArray;
 begin
    SetLength(myRecArray,10);
 end;

      现在提供一些背景信息，说明为什么TList不容易使用记录类型：

      TList更适合与Class类型一起使用，因为'TMyClass'类型的变量，其中'type TMyClass = class .... end;'可以很容易地“引用”为指针值，这是TList所持有的。

      Record类型的变量是Delphi中的value-Types，而类值是隐式的引用值。您可以将by-reference值视为隐形指针。您不必取消引用它们来获取它们的内容，但是当您将它添加到TList时，您实际上只是添加指向TList的指针，而不是复制或分配任何新内存。

      Remy的答案向你展示了如何完全你想要的东西，而我正在写我的答案只是因为我想警告你关于你所问的细节，并建议你也考虑过替代品。

答案 2 :(得分：11)

您可以查看我们的TDynArray wrapper。它在开源单元中定义，从Delphi 6到XE。

使用TDynArray，您可以使用TIntegerDynArray = array of integer访问任何动态数组（例如TRecordDynArray = array of TMyRecord或TList），例如属性和方法，例如Count, Add, Insert, Delete, Clear, IndexOf, Find, Sort和一些新方法（如LoadFromStream, SaveToStream, LoadFrom和SaveTo允许快速二进制序列化任何动态数组，甚至包含字符串或记录 - CreateOrderedIndex方法也可用于创建个人索引根据动态数组内容。如果愿意，您还可以将数组内容序列化为JSON。 <{1}}或Slice, Reverse方法也可用。

它将处理动态的记录数组，甚至是记录中的记录，其中包含字符串或其他动态数组。

使用外部Copy变量时，可以加快引用动态数组中元素的添加速度。

Count

还有一个type TPerson = packed record sCountry: string; sFullName: string; sAddress: string; sCity: string; sEmployer: string; end; TPersons = array of TPerson; var MyPeople: TPersons; (...) procedure SavePeopleToStream(Stream: TMemoryStream); var aPeople: TPerson; aDynArray: TDynArray; begin aDynArray.Init(TypeInfo(TPersons),MyPeople); aPeople.sCountry := 'France'; aPeople.sEmployer := 'Republique'; aDynArray.Add(aPeople); aDynArray.SaveToStream(Stream); end; // no try..finally Free needed here 类，它允许动态数组内容的内部散列。它非常快且能够散列任何类型的数据（有字符串的标准哈希，但你可以提供自己的 - 甚至可以自定义哈希函数）。

请注意，TDynArrayHashed和TDynArray只是现有动态数组变量的包装器。因此，您可以根据需要初始化TDynArrayHashed包装器，以更有效地访问任何本机Delphi动态数组。

答案 3 :(得分：4)

您可以使用TList，例如：

type
  pRec = ^sRec;
  sRec = record
    Value: Integer;
    ...
  end;

var
  List: TList;
  Rec: pRec;
  I: Integer;
begin
  List := TList.Create;
  try
    for I := 1 to 5 do begin
      GetMem(Rec);
      try
        Rec^.Value := ...;
        ...
        List.Add(Rec);
      except
        FreeMem(Rec);
        raise;
      end;
    end;
    ...
    for I := 0 to List.Count-1 do
    begin
      Rec := pRec(List[I]);
      ...
    end;
    ...
    for I := 0 to List.Count-1 do
      FreeMem(pRec(List[I]));
    List.Clear;
  finally
    List.Free;
  end;
end;

答案 4 :(得分：1)

这完全取决于您要存储的数据类型。

您可以考虑使用 TCollection 和 TCollectionItem 。

以下是来自工作单位的（已编辑的）代码，其中我使用TCollection从文件夹中读取报告定义列表。每个报告都包含一种模板和一个必须与文件名一起存储的SQL语句。

由于它是经过编辑的，并且使用了我自己的一些单元（TedlFolderRtns将文件读入内部列表，仅命名一个），因此该示例非常简单，非常有用。通过一些替换，您可以适应您的需要。

在帮助中查找TCollection，你可以用它做很多事情。它使您的代码处理能够很好地组合在一个类似于类的结构中。

  unit cReports;
  interface
  uses
     SysUtils, Classes, XMLDoc, XMLIntf, Variants,
     // dlib - Edelcom
     eIntList, eProgSettings,eFolder ;
  type

     TReportDefItem = class(TCollectionItem)
     private
        fSql: string;
        fSkeleton: string;
        fFileName: string;
        procedure Load;
        procedure SetFileName(const Value: string);
     public
        constructor Create(Collection:TCollection); override;
        destructor Destroy ; override;

        property FileName: string read fFileName write SetFileName;
        property Sql : string read fSql write fSql;
        property Skeleton : string read fSkeleton write fSkeleton;
     end;

     TReportDefList = class(TCollection)
     private
        function OsReportFolder: string;
        function GetAction(const Index: integer): TReportDefItem;
     public
        constructor Create(ItemClass: TCollectionItemClass);
        destructor Destroy; override;

        procedure LoadList;

        function Add : TReportDefItem;
        property Action [ const Index:integer ]: TReportDefItem read GetAction;
     end;

  implementation

  { TReportDefList }

  constructor TReportDefList.Create(ItemClass: TCollectionItemClass);
  begin
     inherited;
  end;

  destructor TReportDefList.Destroy;
  begin
     inherited;
  end;
  function TReportDefList.Add: TReportDefItem;
  begin
     Result := TReportDefItem( Add() );
  end;

  function TReportDefList.GetAction(const Index: integer): TReportDefItem;
  begin
     if (Index >= 0) and (Index < Count)
     then Result := TReportDefItem( Items[Index] )
     else Result := Nil;
  end;

  procedure TReportDefList.LoadList;
  var Folder : TedlFolderRtns;
      i : integer;
      Itm : TReportDefItem;
  begin
     Folder := TedlFolderRtns.Create;
     try
        Folder.FileList( OsReportFolder,'*.sw.xml', False);
        for i := 0 to Folder.ResultListCount -1 do
        begin
          Itm := Add();
          Itm.FileName := Folder.ResultList[i];
        end;
     finally
        FreeAndNil(Folder);
     end;
  end;

  function TReportDefList.OsReportFolder: string;
  begin
     Result := Application.ExeName + '_RprtDef';
  end;

  { TReportDefItem }

  constructor TReportDefItem.Create(Collection: TCollection);
  begin
     inherited;
     fSql := '';
     fSkeleton := '';
  end;

  destructor TReportDefItem.Destroy;
  begin
    inherited;
  end;

  procedure TReportDefItem.Load;
  var XMLDoc : IXMLDocument;
      TopNode : IXMLNode;
      FileNode : IXmlNode;
      iWebIndex, iRemoteIndex : integer;
      sWebVersion, sRemoteVersion: string;
      sWebFileName: string;
  begin
     if not FileExists(fFileName ) then Exit;

     XMLDoc := TXMLDocument.Create(nil);
     try
        XMLDoc.LoadFromFile( fFileName );
        XMLDoc.Active := True;

        TopNode := XMLDoc.ChildNodes.FindNode('sw-report-def');
        if not Assigned(TopNode) then Exit;

        FileNode := TopNode.ChildNodes.First;
        while Assigned(FileNode) do
        begin
           fSql := VarToStr( FileNode.Attributes['sql'] );
           fSkeleton := VarToStr(  FileNode.Attributes['skeleton'] );
           FileNode := FileNode.NextSibling;
        end;
        XMLDoc.Active := False;
     finally
        XMLDoc := Nil;
     end;
  end;

  procedure TReportDefItem.SetFileName(const Value: string);
  begin
     if fFileName <> Value
     then begin
        fFileName := Value;
        Load;
     end;
  end;
  end.

用作：

fReports := TReportDefList.Create( TReportDefItem );
fReports.LoadList();

答案 5 :(得分：1)

我们在这里遇到一个类似的问题，带有一个通用的记录列表。希望以下psuedo代码有所帮助。

type
  PPat = ^TPat;
  TPat = record
    data: integer;
  end;

...
var
    AList: TList<PPat>;

...
procedure TForm1.Button1Click(Sender: TObject);
var
  obj: PPat;
begin
  obj := AList[0];
  obj.data := 1;
  Assert(obj.data = AList[0].data);  // correct
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  obj: PPat;
begin
  AList := TList<PPat>.Create;
  GetMem(obj, SizeOf(TPat));  // not shown but need to FreeMem when items are removed from the list
  obj.data := 2;
  AList.Add(obj);
end;

答案 6 :(得分：0)

如果使用的是不存在泛型的较早版本的Delphi，请考虑从TList继承并重写Notify方法。添加项目时，分配内存，复制添加的指针内存内容并覆盖列表中的内容。删除时，仅释放内存。 

  TOwnedList = class(TList)
  private
    FPtrSize: integer;
  protected
    procedure Notify(Ptr: Pointer; Action: TListNotification); override;
  public
    constructor Create(const APtrSize: integer);
  end;

  constructor TOwnedList.Create(const APtrSize: integer);
  begin
    inherited Create();
    FPtrSize := APtrSize;
  end;

  procedure TOwnedList.Notify(Ptr: Pointer; Action: TListNotification);
  var
    LPtr: Pointer;
  begin
    inherited;
    if (Action = lnAdded) then begin
      GetMem(LPtr, FPtrSize);
      CopyMemory(LPtr, Ptr, FPtrSize); //May use another copy kind
      List^[IndexOf(Ptr)] := LPtr;
    end else if (Action = lnDeleted) then begin
      FreeMem(Ptr, FPtrSize);
    end;
  end;

用法：

...
LList := TOwnedList.Create(SizeOf(*YOUR RECORD TYPE HERE*));
LList.Add(*YOU RECORD POINTER HERE*);
...
  • 请注意，在我确实使用CopyMemory（LPtr，Ptr，FPtr​​Size）的地方，您可以使用其他复制方式。我的列表旨在存储带有指针引用的记录，因此它不管理字段的内存。

答案 7 :(得分：0)

使用System.Generics.Collections中的GeneriсTList。 如果您需要按引用访问通用TList中的记录，并且请勿复制记录： 使用 List.List -直接访问TList数组。

MyList := TList<TTestRec>.Create; 
[...] 

var lRecP: PTestRec; // (PTestRec = ^TTestRec)
lRecP := @MyList.List[i];

现在您无需复制即可访问Tlist数组中的记录。

相关问题
最新问题