此问题已在qt社区中发布:https://forum.qt.io/topic/106930/how-to-run-lupdate-with-a-qmake-config
我在项目文件中使用了这样的构造:
LANGUAGES = de
TRANSLATION_NAME = authorization
include(../../gen_translations.pri)
gen_translations.pri如下所示:
# parameters: var, prepend, append
defineReplace(prependAll) {
for(a,$$1):result += $$2$${a}$$3
return($$result)
}
TRANSLATIONS = $$prependAll(LANGUAGES, $$PWD/libs/$$TRANSLATION_NAME/translations/lib$${TRANSLATION_NAME}_, .ts)
TRANSLATIONS_FILES =
qtPrepareTool(LRELEASE, lrelease)
for(tsfile, TRANSLATIONS) {
qmfile = $$shadowed($$tsfile)
qmfile ~= s,.ts$,.qm,
qmdir = $$dirname(qmfile)
!exists($$qmdir) {
mkpath($$qmdir)|error("Aborting.")
}
command = $$LRELEASE -removeidentical $$tsfile -qm $$qmfile
system($$command)|error("Failed to run: $$command")
TRANSLATIONS_FILES += $$qmfile
}
for(qmentry, $$list($$TRANSLATIONS_FILES)) {
qmpath = $$OUT_PWD/../translations
qmpathname = $$replace(qmpath,/,)
qmpathname = $$replace(qmpathname,\.,)
qmpathname = $$replace(qmpathname,:,)
qmpathname = $$replace(qmpathname," ",)
qmentity = qmfiles_$${qmpathname}
eval($${qmentity}.files += $$qmentry)
eval($${qmentity}.path = $$qmpath)
INSTALLS *= $${qmentity}
}
它会为我生成*.qm
文件,并通过make install将其移动到定义的位置。
我不希望qmake
在我的开发机器上为每个构建都执行全部工作。因此,我想通过将其包装为qmake
来使其成为条件:
translate{
LANGUAGES = de
TRANSLATION_NAME = authorization
include(../../gen_translations.pri)
}
这样,我可以决定何时获取*.qm
文件,何时获取。
但是后来我无法在项目文件上预先运行lupdate
,因为它被该条件阻止了。
我确定有人会更好地完成任务。
谢谢。
答案 0 :(得分:0)
我在这里分享vmpk project的食谱。我是从Arora项目中借用的(我认为)。它比您的简单得多,我让qmake决定是否需要像擦除其他任何编译器一样在擦除输出或更改输入.ts时重新生成任何.qm文件。
updateqm.pri
# update translations
isEmpty(QMAKE_LRELEASE) {
win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\\lrelease.exe
else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
!exists($$QMAKE_LRELEASE) { QMAKE_LRELEASE = lrelease }
}
updateqm.input = TRANSLATIONS
updateqm.output = $$OUT_PWD/${QMAKE_FILE_BASE}.qm
updateqm.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$OUT_PWD/${QMAKE_FILE_BASE}.qm
updateqm.CONFIG += no_link target_predeps
QMAKE_EXTRA_COMPILERS += updateqm
project.pro:
TRANSLATIONS += \
translations/project_en.ts \
translations/project_cs.ts \
translations/project_de.ts \
translations/project_es.ts \
translations/project_fr.ts \
translations/project_ru.ts
include(updateqm.pri)
使用此项目文件,您可以像往常一样:
lupdate project.pro
无论如何,Qt5 has a builtin CONFIG+=lrelease
选项使“ updateqm.pri”不推荐使用。