Question

我试图使用QB64 V1.2编译QB程序DIMORDIN.BAS（旧QB4.5软件包中包含的示例）。

编译不会指示错误，但是程序的执行令人惊讶……大多数排序类型的执行都会导致分段错误。

调试代码，我发现导致此结果的原因是语言函数SWAP，证据是该语言函数无法交换复杂和/或用户定义的类型。这样的行：SWAP MatrOrd(Riga), MatrOrd(Riga + Scarto)给出了分段错误。

您有解决方案吗？为什么QB64不符合QB4.5的此功能？

以下代码是出现分段错误的SUB的原始代码（不幸的是，我只有意大利语版本）。

我不能在此处发布完整的代码，因为它大于30,000个字符。

SUB OrdShell STATIC

    ' Imposta lo scarto per il confronto a met del numero di record in MatrOrd:
    Scarto = RigheMass \ 2

    PRINT
    DO WHILE Scarto > 0 ' Cicla finch Scarto non diventa zero.
        Limite = RigheMass - Scarto
        DO
            Scambi = FALSO ' Presume non vi siano stati scambi
            ' con questo valore di Scarto.

            ' Confronta elementi e scambia quelli non in ordine:
            FOR Riga = 1 TO Limite
                IF MatrOrd(Riga).Lung > MatrOrd(Riga + Scarto).Lung THEN
                    SWAP MatrOrd(Riga), MatrOrd(Riga + Scarto)
                    ScambiaBarre Riga, Riga + Scarto
                    Scambi = Riga
                END IF
            NEXT Riga

            ' Al passaggio successivo ordina solo fino al punto dell'ultimo
            ' scambio:
            Limite = Scambi - Scarto
        LOOP WHILE Scambi

        ' Nessuno scambio al precedente valore di scarto; lo dimezza:
        Scarto = Scarto \ 2
    LOOP
END SUB

为帮助您理解SUB，我添加了程序的声明部分：

' Definisce il tipo di dati usato per contenere i dati delle barre:
TYPE TipoOrd
    Lung AS INTEGER ' Lunghezza della barra (l'elemento di
    ' confronto nei vari ordinamenti)
    ValColore AS INTEGER ' Colore della barra
    StringaBarra AS STRING * 43 ' La barra (una stringa di 43 caratteri)
END TYPE

' Dichiara le costanti globali:
CONST FALSO = 0, VERO = NOT FALSO, COLONNASIN = 49
CONST NUMOPZIONI = 11, NUMORDINAMENTI = 6

' Dichiara le variabili globali e alloca loro spazio nella memoria. MatrOrd
' e BackupOrd sono matrici del tipo di dati TipoOrd definito sopra:
DIM SHARED MatrOrd(1 TO 43) AS TipoOrd, BackupOrd(1 TO 43) AS TipoOrd
DIM SHARED LeggendaOpzioni(1 TO NUMOPZIONI) AS STRING * 14
DIM SHARED TempoIniz AS SINGLE
DIM SHARED PrimoPiano, Sfondo, Silenzio, Pausa
DIM SHARED Selezione, RigheMass, RigheIniz, ColoriMass

我编写了以下小代码来演示函数SWAP产生的问题：

$CONSOLE:ONLY
_DEST _CONSOLE

TYPE TipoOrd
    Lung AS INTEGER ' Lunghezza della barra (l'elemento di
    ' confronto nei vari ordinamenti)
    ValColore AS INTEGER ' Colore della barra
    StringaBarra AS STRING * 43 ' La barra (una stringa di 43 caratteri)
END TYPE

DIM a(1 TO 43) AS TipoOrd

a(1).Lung = 2: a(2).Lung = 4
PRINT a(1).Lung, a(2).Lung
SWAP a(1), a(2)
PRINT a(1).Lung, a(2).Lung

END

Answer 1

喝咖啡后，我解决了编写子例程SWAPT的问题，该子例程执行用户定义类型TipoOrd的变量之间的交换。

将SWAP函数替换为SWAPT子例程后，程序正确运行。

但是，有关QB64和QB4.5之间的不合规性的问题仍然存在。

这是修改后的函数和SWAPT子例程：

SUB OrdShell STATIC

    ' Imposta lo scarto per il confronto a met del numero di record in MatrOrd:
    Scarto = RigheMass \ 2

    PRINT
    DO WHILE Scarto > 0 ' Cicla finch Scarto non diventa zero.
        Limite = RigheMass - Scarto
        DO
            Scambi = FALSO ' Presume non vi siano stati scambi
            ' con questo valore di Scarto.

            ' Confronta elementi e scambia quelli non in ordine:
            FOR Riga = 1 TO Limite
                IF MatrOrd(Riga).Lung > MatrOrd(Riga + Scarto).Lung THEN
                    REM SWAP MatrOrd(Riga), MatrOrd(Riga + Scarto)                             
                    SWAPT MatrOrd(Riga), MatrOrd(Riga + Scarto)

                    ScambiaBarre Riga, Riga + Scarto
                    Scambi = Riga
                END IF
            NEXT Riga

            ' Al passaggio successivo ordina solo fino al punto dell'ultimo
            ' scambio:
            Limite = Scambi - Scarto
        LOOP WHILE Scambi

        ' Nessuno scambio al precedente valore di scarto; lo dimezza:
        Scarto = Scarto \ 2
    LOOP
END SUB

SUB SWAPT (a AS TipoOrd, b AS TipoOrd)
    SWAP a.Lung, b.Lung
    SWAP a.ValColore, b.ValColore
    SWAP a.StringaBarra, b.StringaBarra
END SUB

Answer 2

我已经编写了此QB64 v1.3a代码，用于成功交换结构：

TYPE Struct1
    Element1 AS INTEGER
    Element2 AS INTEGER
END TYPE
DIM SHARED StructA(10) AS Struct1
DIM SHARED StructB(10) AS Struct1
StructA(1).Element1 = -1
StructB(1).Element1 = 1
PRINT "StructA="; StructA(1).Element1
PRINT "StructB="; StructB(1).Element1
PRINT "Swap:"
SWAP StructA(1), StructB(1)
PRINT "StructA="; StructA(1).Element1
PRINT "StructB="; StructB(1).Element1
END

使用具有用户定义类型的QB64函数SWAP的分段故障问题

2 个答案: