Question

我最近一直在玩增强现实（并且也有很多乐趣！）我已经能够创建PaperVision原语（立方体，圆柱体，圆锥体等......并与它们配合使用）但是添加了DAE模型被证明是虚幻的！

var cubeMaterialList:MaterialsList = new MaterialsList( { all: new FlatShadeMaterial(light, 0x0099FF, 0x0066AA) } );

            var cube:Cube = new Cube(cubeMaterialList,
                                     30,
                                     30,
                                     30);

            cube.z += 15;

            mainContainer.addChild(cube);

一切正常！

我用它来导入/尝试导入dae！

private var mCollada:Collada;
private var universe:DisplayObject3D;
mCollada = new Collada("sample.dae");
universe = new DisplayObject3D();
universe.addChild(mCollada);
        mainContainer.addChild(universe);

我已经使用这种将DAE导入非增强现实PaperVision项目的方法，这是一种享受！所以只是想知道是否有人有幸用AR导入DAE！

Answer 1

Click here to view a video of the necessary imports and working demo on my site.

我注意到你使用的是Collada Class，而不是DAE，类，它们的行为有点不同，如视频abobe中所示。

同样重要的是要注意，您可能正确地执行此操作，并且模型或甚至纹理可能存在问题。如果没有加载纹理，您应该立即从控制台知道。尝试创建ColorMaterial并创建一个MaterialsList对象，将“all”属性设置为您创建的ColorMaterial。最后通过实例化或加载方法将列表传递给Collada或DAE Classes的实例化。还要确保相机未放大以关闭，可能会将3D物体留在其后面。最后使用比例尺，并非所有模型都以相同的比例进入，而使用Collada类而不是DAE，似乎可以大大提升模型，如上面的视频链接所示。

我最近在筹备Tony Hawk XI网站时，有很多时间玩FlarToolkit / Papervision3D / Collada合作伙伴。

- 你需要什么

IDE，我使用FlashDevelop3 RC2，但Flex Builder或您选择的IDE都可以使用。
Papervision3D 2.0 Whiteshark，（最新版本）
Flex 3.3 SDK
耐心

- 找到并准备模型

将Google 3D Warehouse用于我的Collada文件。
接下来将“.skp”草图文件放入Google Sketchup。
确保草图窗口具有焦点并同时按下CTRL和A. （全选）
前往编辑，然后转到下拉列表的底部，通常会说明您选择了多少组。
选择爆炸。
重复直到你不能再爆炸了。（如果你正在使用像你应该的低多边形模型，这不应该花很长时间。）
CTRL + A再次选择全部。
转到文件＆gt;出口＆gt; 3D模型并选择“.dae”//如果您没有拥有Sketchup，则.dae扩展名不可用，请查找工作:)（基本上.dae包含在“.skp”
您现在将拥有一个.dae文件，以及一个具有相同EXACT名称的文件夹，其中包含与其内部模型相关的纹理。

- 导入/解析模型并显示它

package 
{
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.utils.ByteArray;
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMat;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.pv3d.FLARCamera3D;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.render.LazyRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.objects.parsers.Collada;
    import org.papervision3d.objects.parsers.DAE;
/**
 * ...
 * @author Brian Hodge
 */
public class Main extends Sprite 
{
    [Embed(source="../lib/camera_para.dat", mimeType="application/octet-stream")]
    private var CameraParameters:Class;

    [Embed(source="../lib/collada.pat", mimeType="application/octet-stream")]
    private var MarkerPattern:Class;

    private var cameraParameters:FLARParam;
    private var markerPattern:FLARCode;
    private var raster:FLARRgbRaster_BitmapData;
    private var detector:FLARSingleMarkerDetector;

    private var cam:Camera;
    private var vid:Video;
    private var capture:BitmapData;

    private var cam3D:FLARCamera3D;
    private var scene3D:Scene3D;
    private var viewPort:Viewport3D;
    private var mainContainer:FLARBaseNode;
    private var renderer:LazyRenderEngine;

    private var trans:FLARTransMatResult;
    private var prevSet:Boolean = false;
    private var prevZ:Number = 0;

    private var _collada:Collada;
    private var _dae:DAE;

    public function Main():void 
    {
        cameraParameters = new FLARParam();
        cameraParameters.loadARParam(new CameraParameters() as ByteArray);

        markerPattern = new FLARCode(16, 16);
        markerPattern.loadARPatt(new MarkerPattern());

        cam = Camera.getCamera();
        cam.setMode(640, 480, 30);

        vid = new Video();
        vid.width = 640;
        vid.height = 480;
        vid.attachCamera(cam);
        addChild(vid);

        capture = new BitmapData(vid.width, vid.height, false, 0x0);
        capture.draw(vid);

        raster = new FLARRgbRaster_BitmapData(capture);
        detector = new FLARSingleMarkerDetector(cameraParameters, markerPattern, 80);

        cam3D = new FLARCamera3D(cameraParameters);

        scene3D = new Scene3D();

        mainContainer = new FLARBaseNode();
        scene3D.addChild(mainContainer);

        viewPort = new Viewport3D(vid.width, vid.height);
        viewPort.scaleX = viewPort.scaleY = 2;
        addChild(viewPort);

        renderer = new LazyRenderEngine(scene3D, cam3D, viewPort);

        _dae = new DAE();
        _dae.load("assets/dae/apc.dae");
        _dae.rotationZ -= 90;
        mainContainer.addChild(_dae);

        /*
        _collada = new Collada("assets/dae/apc.dae");
        _collada.scale = 0.05;
        _collada.rotationZ -= 90;
        mainContainer.addChild(_collada);
        */

        trans = new FLARTransMatResult();

        this.addEventListener(Event.ENTER_FRAME, mainEnter);
    }
    private function mainEnter(e:Event):void 
    {
        capture.draw(vid);

        if (detector.detectMarkerLite(raster, 80) && detector.getConfidence() > 0.5)
        {
            detector.getTransformMatrix(trans);

            mainContainer.setTransformMatrix(trans);
            mainContainer.visible = true;
            renderer.render();
        }
        else
        {
            mainContainer.visible = false;
            renderer.render();
        }
    }
}

}

希望这一切对您有所帮助，我建议您继续玩它并继续熟悉它。

Answer 2

@Brady，

嘿，我认为这可能是错误：

[Embed（source =“pat1.pat”，mimeType =“application / octet-stream”）] private var CameraParameters：Class;

[Embed（source =“pat1.pat”，mimeType =“application / octet-stream”）] private var MarkerPattern：Class;

在“CameraParameters”中你应该嵌入“camera_para.dat”而不是 - pat1.pat 。试试这个。

Answer 3

我在this site实际上找到了一些很好的信息。我用那里的代码将模型导入到我的AR中。它概述了一种导入collada模型的非常简单的方法。我刚刚采用了示例FlarToolkit示例（simpleCube示例）并在该文章中添加了代码，这足以让我前进。

以下是代码：

package {
    import org.papervision3d.lights.PointLight3D;
    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.materials.shadematerials.FlatShadeMaterial;
    import org.papervision3d.materials.utils.MaterialsList;
    import org.papervision3d.materials.*;
    import org.papervision3d.materials.utils.*;
    import org.papervision3d.materials.shadematerials.*;
    import org.papervision3d.objects.primitives.Cube;
    import org.papervision3d.objects.primitives.Cylinder;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.parsers.Collada;
    import flash.events.*;

    public class SimpleCube extends PV3DARApp {

        public var FAlogo:DisplayObject3D;
        public var light                        :PointLight3D;

        public function SimpleCube() {
            this.init('Data/camera_para.dat', 'Data/flarlogo.pat');
        }

        protected override function onInit():void {
            super.onInit();
            this.addEventListener( Event.ENTER_FRAME, EROnEnterFrame );

            // let there be light
            this.light = new PointLight3D;
            this.light.x = 0;
            this.light.y = 1000;
            this.light.z = -1000;

            // cow model
            FAlogo = new Collada("http://papervision2.com/wp-content/downloads/dae/cow.dae");
            FAlogo.rotationZ = -90;
            FAlogo.rotationY = -90;
            FAlogo.x = -100;
            FAlogo.z = 100;
            FAlogo.scale = 0.1;

            // re-orient the logo model before adding it to the scene

            this._baseNode.addChild(this.FAlogo);
        }

        private function EROnEnterFrame( event :Event ):void
        {
            // spins the cow yay!
            FAlogo.yaw(3);
        }
    }
}

AS3 DAE增强现实PaperVision 3D

3 个答案:

- 你需要什么

- 找到并准备模型

- 导入/解析模型并显示它