将单元格定义扩展到CellFrameLabels定义

Question

我正在创建一个包含写入文档样式的笔记本。我希望Mathematica的行为类似于LaTeX，因为当我写一个"Definition"单元格时，它会写"Definition [Chapter#].[Definition#]"。

要明白我的意思，请执行以下操作。在空白笔记本中创建一个单元格并将样式修改为"Chapter"。您可以通过选择单元格并转到Format->Style->Other，输入"Chapter"。

来执行此操作

现在转到Format->Edit StyleSheet...。在输入框中输入Chapter。这将生成一个标记为Chapter的单元格。选择该单元格，然后单击Cell->Show Expression。此时选择您在那里看到的所有文本，并将其替换为以下内容：

Cell[StyleData["Chapter"],
 CellFrame->{{0, 0}, {0, 0}},
 ShowCellBracket->Automatic,
 CellMargins->{{42, 27}, {10, 30}},
 CounterIncrements->"Chapter",
 CounterAssignments->{{"Section", 0}, {"Definition", 0}},
 FontFamily->"Verdana",
 FontSize->24,
 FontWeight->"Bold",
 CellFrameLabels->{{
    Cell[
     TextData[{
       "Chapter ",
       CounterBox["Chapter"]
       }], "ChapterLabel", CellBaseline -> Baseline], Inherited}, {
   Inherited, Inherited}},
 FontColor->RGBColor[0.641154, 0.223011, 0.0623026]]

这将改变章节单元格的显示方式。我改变了颜色和字体。对我来说最重要的是CellFrameLabels。注意到我已经这样做，所以每次创建章节单元格时它都会显示：Chapter [Chapter Number]。

在上图中，我创建了几个章节单元格，并添加了文本：": Title of Chapter #"。

这很简单，我们可以创建任何单元格，应用定义并利用计数器的优势来标记单元格。

我注意到有些书的方法是如何包含在框中的。所以在这种情况下，我想创建一个包含Definition的框。以下是我对单元格"Definition"的定义的蹩脚尝试。

Cell[StyleData["Definition"],
 CellFrame->{{0, 0}, {0, 2}},
 ShowCellBracket->Automatic,
 CellMargins->{{27, 27}, {0, 8}},
 PageBreakWithin->False,
 CellFrameMargins->16,
 CellFrameColor->RGBColor[0.641154, 0.223011, 0.0623026],
 Background->RGBColor[0.963821, 0.927581, 0.844465],
 FontFamily->"Verdana",
 CounterIncrements->"Definition",
 FontSize->12,
 CellFrameLabels->{{
    Cell[
     TextData[{
       "Definition ",
       CounterBox["Chapter"], ".", 
       CounterBox["Definition"]
       }], "DefinitionLabel", CellBaseline -> Baseline], Inherited}, {
   Inherited, Inherited}},
 ]

以下是笔记本中的外观：

这是一个问题：有没有办法制作单元格的CellFrameLabels部分？我希望标签具有相同的背景，并与其他文本内联。以下是我希望它看起来的屏幕截图：

我已将“标签”加粗字体和蓝色。这是用户无法修改的内容。

Answer 1

我认为不可能按照你想要的方式去做。 CellLabel只能是文字，而CellDingbat和CellFrameLabels都可以是任意的单元格表达式。

如果单元格只有一行，CellDingbat -> ...和CellFrameLabels -> {{...,None},{None,None}}都有效。但是不要为多个线路单元自动调整大小（至少据我所知）。例如：

Cell["Abcdefg", "Text",
 CellFrame->{{0, 1}, {0, 2}},
 CellMargins->{{30, 24}, {6, 6}},
 CellFrameMargins->0,
 CellFrameColor->RGBColor[0, 0, 1],
 CellFrameLabels->{{Cell[" Definition 1.1  ", "Text", 
   CellFrame -> {{2, 0}, {0, 2}}, CellFrameMargins -> 0], None}, {None, None}},
 CellFrameLabelMargins->0,
 Background->RGBColor[0, 1, 1]]

将CellFrameLabel放在顶部没有这个问题，但我不知道如何将它对齐到左边......

Cell["Abcde", "Text",
 CellFrame->{{1, 1}, {0, 2}},
 CellMargins->{{30, 24}, {6, 6}},
 CellFrameMargins->0,
 CellFrameColor->RGBColor[0, 0, 1],
 CellFrameLabels->{{None, None}, {None, 
    Cell[" Definition 1.1 ", "Text", 
     CellFrame -> {{2, 2}, {0, 2}}, CellFrameMargins -> 0]}},
 CellFrameLabelMargins->0,
 Background->RGBColor[0, 1, 1]]

我认为最好的解决方案可能是在单元格内容中包含“定义ch.def：”。

Cell[TextData[{
 Cell["Definition 1.1:   ", Editable->False, Selectable->False, Deletable->False],
 "Abcdefg"}], "Text",
 CellFrame->{{1, 1}, {0, 2}},
 CellMargins->{{30, 24}, {6, 6}},
 CellFrameColor->RGBColor[0, 0, 1],
 Background->RGBColor[0, 1, 1]]

使其不能被普通用户删除，并且它可能几乎与单元格（框架）标签一样好。它可以包括计数器，以便它自动显示正确的编号。唯一的问题是它不会自动出现，但如果您只是复制一个预先存在的单元格，那么这不是太大的问题。

---

编辑：添加创建不可删除计数器的input alias

首先我们得到当前的输入别名

oldAliases = InputAliases /. Options[EvaluationNotebook[], InputAliases];

然后用我们的新别名替换任何现有的别名 Esc def Esc ：

newAliases = 
  Append[DeleteCases[oldAliases, "def" -> _], 
   "def" -> Cell[TextData[
     RowBox[StyleBox[#, FontWeight->"Bold", FontColor->Blue]&/@{"Definition ", 
      CounterBox["Chapter"], ".", CounterBox["Definition"], ":   "}]],(*"Text",*)
     Editable -> False, Selectable -> False, Deletable -> False]];  
SetOptions[EvaluationNotebook[], InputAliases -> newAliases]

由于我没有你的样式表，我需要设置几个计数器：

CellPrint[Cell["Setting the counters", "Text", 
  CounterAssignments -> {{"Chapter", 2}, {"Definition", 3}}]]

现在我可以在现有单元格中使用别名 - 它继承了父单元格的样式（除非另有说明）：

---

另一种选择是使palette与样式表一致。这很有用，因为只有limited number MenuCommandKey个值可用于新样式（n.b.覆盖默认样式会让人感到困惑）。有关此类调色板的示例，请参阅this answer。