Question

我在CMake中尝试CTest，以便使用make test目标自动运行我的一些测试。问题是CMake没有“理解”我愿意运行的测试必须构建，因为它是项目的一部分。

所以我正在寻找一种明确指定这种依赖关系的方法。

Answer 1

可以说是一个bug in CMake（之前跟踪的here），这不是开箱即用的。解决方法是执行以下操作：

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

然后你可以运行make check，它将编译并运行测试。如果您有多个测试，那么您必须在上面的行中使用DEPENDS exe1 exe2 exe3 ...。

Answer 2

实际上有一种方法可以使用make test。您需要将测试可执行文件的构建定义为其中一个测试，然后在测试之间添加依赖项。那就是：

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Answer 3

我使用了richq的答案变体。在顶级CMakeLists.txt中，我添加了一个自定义目标build_and_test，用于构建和运行所有测试：

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

在CMakeLists.txt下的各个子项目test/文件中，我将每个测试可执行文件添加为build_and_test的依赖项：

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

使用这种方法，我只需要make build_and_test而不是make test（或make all test），它的好处是只构建测试代码（及其依赖项）。遗憾的是我不能使用目标名test。在我的情况下，它并没有那么糟糕，因为我有一个顶级脚本，通过调用cmake然后make进行树外调试和发布（和交叉编译）构建，并且它将test翻译为build_and_test。

显然，GTest的东西不是必需的。我碰巧使用/喜欢Google Test，并希望分享一个与CMake / CTest一起使用它的完整示例。恕我直言，这种方法还有一个好处，就是允许我使用ctest -V，它会在测试运行时显示Google Test输出：

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Answer 4

如果您尝试模仿make check，您可能会发现此Wiki条目很有用：

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

我刚刚检查过它是否成功（CMake 2.8.10）。

Answer 5

让自己避免头痛：

make all test

为我开箱即用，并在运行测试之前构建依赖项。鉴于它有多简单，它几乎使原生make test功能变得方便，因为即使您的代码被破坏，它也可以让您选择运行最后的编译测试。

Answer 6

这是我锤击并一直使用的：

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

YMMV

Answer 7

如果您使用的是CMake> = 3.7，则建议的方法是使用fixtures：

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config $<CONFIG>
  --target test
)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)

Answer 8

德里克的回答，经过简化和评论：

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

这不是完全正确的，因为它不能解决运行ninja all test的并发问题，以防万一有人这样做。相反，因为现在有两个忍者进程。

（Ftr，我也分享了此解决方案here。）

Answer 9

对于 CMake 3.10 或更高版本，另一种选择是使用 TEST_INCLUDE_FILES 目录属性来设置一个脚本，该脚本在运行测试之前触发构建。在最外层的 CMakeLists.txt 中添加以下代码：

set_property(DIRECTORY APPEND
    PROPERTY TEST_INCLUDE_FILES "${CMAKE_CURRENT_BINARY_DIR}/BuildTestTarget.cmake")
file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/BuildTestTarget.cmake"
   "execute_process(COMMAND \"${CMAKE_COMMAND}\""
   " --build \"${CMAKE_BINARY_DIR}\""
   " --config \"\$ENV{CMAKE_CONFIG_TYPE}\")")

实际测试配置通过环境变量 CMAKE_CONFIG_TYPE 传递到构建。（可选）您可以添加 --target 选项以仅构建测试所需的目标。

Answer 10

以上所有答案都很完美。但实际上CMake使用CTest作为其测试工具，因此执行任务的标准方法（我认为是）：

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

然后运行 cmake 和 make 来构建目标。之后，您可以运行 make test ，也可以运行

ctest

你会得到结果。这是在CMake 2.8下测试的。

查看详情：http://cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing

Answer 11

所有答案都很好，但是它们意味着违反传统以通过命令make test进行测试。我做过这个伎俩：

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

这意味着测试包括构建（可选）和运行可执行目标。

CMake＆amp; CTest：make test不构建测试

11 个答案: