Question

我是xsl的新手。我想从

转换xml

<result name="response" numFound="1" start="0">
  <doc>
    <str name="q">what</str>
    <arr name="suggestion">
                <str>what1</str>
                <str>what2</str>
   </arr>
  </doc>
</result>

要，

<result name="response" numFound="2" start="0">
  <doc>
    <str name="q">what</str>
    <str name="suggestion">what1</str>
  </doc>
  <doc>
    <str name="q">what</str>
    <str name="suggestion">what2</str>
  </doc>
</result>

我可以提取文本，“what1”和“what2”使用，

<xsl:template match="/response/result[@name='response']">
             <xsl:for-each select="./doc/arr[@name='suggestion']/str">
                    <xsl:value-of select="normalize-space(.)"/>
                    <xsl:value-of select="$endl"/>
             </xsl:for-each>
    </xsl:template>

但我不知道如何将它包含在输出xml格式中。任何人都可以帮忙......

附加功能：

有人可以告诉我是否可以在名为<float name="score">的输出文档中添加一个字段，每个文档会增加100个字段吗？

例如）输出：

   <response>
      <lst name="responseHeader">
        <int name="status">0</int>
        <int name="QTime">1</int>
        <lst name="params">
          <str name="indent">on</str>
          <str name="q">"what"</str>
        </lst>
      </lst>
      <result numFound="2" name="response" start="0">
        <doc>
          <str name="query">what</str>
          <str>what1</str>
          <float name="score">100</float>
        </doc>
        <doc>
          <str name="query">what</str>
          <str>what2</str>
          <float name="score">200</float>
        </doc>
        <doc>
          <str name="query">what</str>
          <str>what3</str>
          <float name="score">300</float>
        </doc>
      </result>
    </response>

你能说出我想用什么功能吗？

Answer 1

以下样式表会根据您的输入生成所需的结果。它可能太宽松或太严格，但由于我不知道您的确切要求或输入的架构，这是最好的努力。请以此作为起点，但要进行适当的测试并调查我提供的内容的含义。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:copy-of select="@*" />
            <xsl:attribute name="numFound"><xsl:value-of select="count(doc/arr[@name='suggestion']/str)" /></xsl:attribute>
            <xsl:apply-templates select="doc/arr[@name='suggestion']" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="arr[@name='suggestion']">
        <xsl:for-each select="str">
            <doc>
                <xsl:copy-of select="parent::node()/preceding-sibling:: str[@name='q']" />
                <xsl:variable name="nameAttributeValue" select="parent::node()/@name" />
                <xsl:element name="str"><xsl:attribute name="name"><xsl:value-of select="$nameAttributeValue" /></xsl:attribute><xsl:value-of select="." /></xsl:element>
            </doc>
        </xsl:for-each>
    </xsl:template> 

</xsl:stylesheet>

编辑：回复您的评论：请注意我的第一个模板在/*上的匹配情况。这归结为“任何根元素”。如果XPath表达式以单个/开头，则它始终相对于文档根目录。如果它以double //开头，它基本上意味着当前节点中的任何位置。如果它不是以斜杠开头，则它相对于当前节点。

为了像评论一样处理XML，您需要将样式表更改为...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="node() | @*">
        <xsl:apply-templates select="node() | @*" />
    </xsl:template>

    <xsl:template match="/response/result">
        <xsl:copy>
            <xsl:copy-of select="@*" />
            <xsl:attribute name="numFound"><xsl:value-of select="count(doc/arr[@name='suggestion']/str)" /></xsl:attribute>
            <xsl:apply-templates select="doc/arr[@name='suggestion']" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="arr[@name='suggestion']">
        <xsl:for-each select="str">
            <doc>
                <xsl:copy-of select="parent::node()/preceding-sibling:: str[@name='q']" />
                <xsl:variable name="nameAttributeValue" select="parent::node()/@name" />
                <xsl:element name="str"><xsl:attribute name="name"><xsl:value-of select="$nameAttributeValue" /></xsl:attribute><xsl:value-of select="." /></xsl:element>
            </doc>
        </xsl:for-each>
    </xsl:template> 

</xsl:stylesheet>

我添加的第一个模板是为了确保覆盖XSLT中隐藏的一些默认模板。请注意，如果result中只有一个response元素，这只会提供正确的输出。

就像我说的那样，请学习使用XSLT和XPath表达式，以确保您了解样式表中发生的事情。

Answer 2

以下是OP评论的解决方案，更新了问题：

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="result">
  <result numFound="{count(doc/arr/str)}">
   <xsl:apply-templates select="@*[not(name()='numFound')]"/>
   <xsl:apply-templates/>
  </result>
 </xsl:template>

 <xsl:template match="arr[@name='suggestion']/str">
  <doc>
    <xsl:copy-of select="../../str"/>
    <xsl:copy-of select="."/>
  </doc>
 </xsl:template>

 <xsl:template match="doc|doc/arr">
  <xsl:apply-templates/>
 </xsl:template>
 <xsl:template match="doc/str "/>
</xsl:stylesheet>

应用于以下内容（在OP的评论中提供）XML文档：

<response>
    <lst name="responseHeader">
        <int name="status">0</int>
        <int name="QTime">1</int>
        <lst name="params">
            <str name="indent">on</str>
            <str name="q">"what"</str>
        </lst>
    </lst>
    <result name="response" numFound="1" start="0">
        <doc>
            <str name="q">what</str>
            <arr name="suggestion">
                <str>what1</str>
                <str>what2</str>
            </arr>
        </doc>
    </result>
</response>

生成想要的正确结果：

<response>
   <lst name="responseHeader">
      <int name="status">0</int>
      <int name="QTime">1</int>
      <lst name="params">
         <str name="indent">on</str>
         <str name="q">"what"</str>
      </lst>
   </lst>
   <result numFound="2" name="response" start="0">
      <doc>
         <str name="q">what</str>
         <str>what1</str>
      </doc>
      <doc>
         <str name="q">what</str>
         <str>what2</str>
      </doc>
   </result>
</response>

<强>更新：

在他的问题更新中，OP要求：

有人可以告诉我是否可以在输出的doc文件中添加一个字段 <float name="score">每次增加100 DOC？

这非常容易实现。我们只在现有转换中添加三行代码：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
 </xsl:template>

 <xsl:template match="result">
    <result numFound="{count(doc/arr/str)}">
        <xsl:apply-templates select="@*[not(name()='numFound')]"/>
        <xsl:apply-templates/>
    </result>
 </xsl:template>

 <xsl:template match="arr[@name='suggestion']/str">
    <doc>
        <xsl:copy-of select="../../str"/>
        <xsl:copy-of select="."/>
        <float name="score">
         <xsl:value-of select="100*position()"/>
        </float>    
    </doc>
 </xsl:template>

 <xsl:template match="doc|doc/arr">
    <xsl:apply-templates/>
 </xsl:template>
 <xsl:template match="doc/str "/>
</xsl:stylesheet>

将此转换应用于此XML文档时：

<response>
    <lst name="responseHeader">
        <int name="status">0</int>
        <int name="QTime">1</int>
        <lst name="params">
            <str name="indent">on</str>
            <str name="q">"what"</str>
        </lst>
    </lst>
    <result name="response" numFound="1" start="0">
        <doc>
            <str name="q">what</str>
            <arr name="suggestion">
                <str>what1</str>
                <str>what2</str>
                <str>what3</str>
            </arr>
        </doc>
    </result>
</response>

产生了想要的正确结果：

<response>
   <lst name="responseHeader">
      <int name="status">0</int>
      <int name="QTime">1</int>
      <lst name="params">
         <str name="indent">on</str>
         <str name="q">"what"</str>
      </lst>
   </lst>
   <result numFound="3" name="response" start="0">
      <doc>
         <str name="q">what</str>
         <str>what1</str>
         <float name="score">100</float>
      </doc>
      <doc>
         <str name="q">what</str>
         <str>what2</str>
         <float name="score">200</float>
      </doc>
      <doc>
         <str name="q">what</str>
         <str>what3</str>
         <float name="score">300</float>
      </doc>
   </result>
</response>

XSLT转换xml

附加功能：

2 个答案: