Question

我正在寻找一种在TSQL中将uniqueidentifier增加1的方法。例如，如果id是A6BC60AD-A4D9-46F4-A7D3-98B2A7237A9E，我希望能够选择A6BC60AD-A4D9-46F4-A7D3-98B2A7237A9F。

@rein用于数据导入。我们有一个带有ID的中间表，我们正在生成记录，稍后我们会在导入时加入这些ID。不幸的是，现在其中一些记录会在下一个表中生成几条记录，因此我们需要一个可重现的新ID。

Answer 1

你希望增加Guid的方式对于SQL Server是不正确的，因为Guid是一个在字节组中具有不同字节顺序的结构，请看看： http://sqlblog.com/blogs/alberto_ferrari/archive/2007/08/31/how-are-guids-sorted-by-sql-server.aspx 并注意以下事项：

现在，当我运行修改过的Alberto的查询时，我得到以下序列：   3,2,1,0,5,4,7,6,9,8,15,14,13,12,11,10

这意味着，GUID的字节＃3是最不重要的，GUID的字节＃10是最重要的[从SQL Server ORDER BY子句的角度来看]。

这是一个简单的函数来增加一个唯一的标识符来解释这个：

create function [dbo].[IncrementGuid](@guid uniqueidentifier) 
returns uniqueidentifier 
as 
begin 
declare @guid_binary binary(16), @b03 binary(4), @b45 binary(2), @b67 binary(2), @b89 binary(2), @bAF binary(6)

select @guid_binary = @guid

select @b03 = convert(binary(4), reverse(substring(@guid_binary,1,4)))
select @b45 = convert(binary(2), reverse(substring(@guid_binary,5,2)))
select @b67 = convert(binary(2), reverse(substring(@guid_binary,7,2)))
select @b89 = convert(binary(2), substring(@guid_binary,9,2))
select @bAF = convert(binary(6), substring(@guid_binary,11,6))

if (@b03 < 'FFFFFFFF')
begin
    select @b03 = convert(binary(4), cast(@b03 as int) + 1)
end
else if (@b45 < 'FFFF')
begin
    select @b45 = convert(binary(2), cast(@b45 as int) + 1)
end
else if (@b89 < 'FFFF')
begin
    select @b89 = convert(binary(2), cast(@b89 as int) + 1)
end
else
begin
    select @bAF = convert(binary(6), cast(@bAF as bigint) + 1)
end

return convert(binary(16), reverse(convert(char(4),@b03)) + reverse(convert(char(2),@b45)) + reverse(convert(char(2),@b67)) + convert(char(2),@b89) + convert(char(6),@bAF))
end

请注意，字节6和7不会递增，因为它们包含Guid版本位。但正如其他人指出你真的不应该这样做。在你的情况下，如果你为这些Guids创建一个临时表可能会更好（有两列：一个整数作为索引，第二个生成Guids）。

Answer 2

你可以采用这种方法，但我不考虑溢出低8字节的情况。

declare @guid uniqueidentifier, @binaryUpper8 binary(8), @binaryLower8 binary(8), @binary16 binary(16), @bigint bigint
set @guid = 'A6BC60AD-A4D9-46F4-A7D3-98B2A7237A9E'
set @binary16 = cast(@guid as binary(16))

--harvest lower 8 bytes
select @binaryUpper8= substring(@binary16, 1, 8)
    ,@binaryLower8  = substring(@binary16, 9, 8)
set @bigint = cast(@binaryLower8 as bigint)

--increment
set @bigint = @bigint + 1

--convert back
set @binaryLower8 = cast(@bigint as binary(8))
set @binary16 = @binaryUpper8 + @binaryLower8
set @guid = cast(@binary16 as uniqueidentifier)
select @guid

Answer 3

这是我提出的一种方式，但我希望有更好的方法。

LEFT([ID], 19) + RIGHT(CONVERT(uniqueidentifier, CONVERT(binary(16), CONVERT(binary(16), [ID]) + CONVERT(bigint, 1))), 17) AS 'MyNewID'

增加SQL中的uniqueidentifier

3 个答案: