Question

我想比较两个向量，并查看它们所拥有的项目是否相同，无论项目的顺序如何。

所以..

现在在clojure中：

(= [1 2 3] [3 2 1]) ;=> false

我想：

(other_fun [1 2 3] [3 2 1]) ;=> true

(other_fun [1 2 3 4] [3 2 1]) ;=> false

我找不到像java这样的containsAll

Answer 1

如果您关注重复项，您可以比较它们的频率图。这些是将每个集合元素作为键和出现次数作为值的映射。您可以使用标准函数frequencies创建它们，就像在给定的示例中一样。

不同的顺序，相同数量的重复：

(= (frequencies [1 1 2 3 4])(frequencies [4 1 1 2 3]))

评估true。

不同的顺序，不同数量的重复：

(= (frequencies [1 1 2 3 4])(frequencies [4 1 2 3]))

评估false。

所以，你可以编写一个函数：

(defn other_fun [& colls]
  (apply = (map frequencies colls)))

Answer 2

如果您不关心重复项，可以从两个向量创建集合并进行比较：

(= (set [1 2 3]) (set [3 2 1])) ;=> true

作为一项功能：

(defn set= [& vectors] (apply = (map set vectors)))

Answer 3

如果你不关心重复，其他答案是完全适用和有效的。但是如果你关心重复，可能最简单的比较两个向量的方法是排序和比较：

user=> (= (sort [3 5 2 2]) (sort [2 2 5 3]))
true
user=> (= (sort [3 5 2 2]) (sort [2 5 3]))
false

Answer 4

从中创建集合：

user=> (= (set [1 2 3]) (set [3 2 1]))
true


user=> (defn other_func [col1 col2]
        (= (set col1) (set col2)))
#'user/other_func
user=> (other_func [1 2 3] [3 2 1])
true

Answer 5

你已经在JVM上，所以如果你想要containsAll，那么只需使用containsAll吧？

Answer 6

(defn other_fun
  "checkes the presence of the elements of vec1 in vec2 and vice versa"
  [vec1 vec2]
  (if (or (some nil?
             (for [a vec1 b [vec2]]  (some #(= % a) b)))
       (some nil?
             (for [a vec2 b [vec1]]  (some #(= % a) b))))
    false
    true))

(other_fun [1 2 3] [3 2 1]) ;=> true

(other_fun [1 2 3 4] [3 2 1]) ;=> false

比较clojure中的两个向量，无论项目的顺序如何

6 个答案: