Question

我的Flash应用程序有点大，所以我想在我的应用程序中嵌入一个预加载器，所以任何人都可以告诉我如何在新的'场景'中创建预加载器在预加载完成后加载另一个场景？

提前致谢！

Answer 1

<强>更新

选项1. Flash IDE，一个swf文件

要在使用Flash IDE进行编译时使用嵌入式预加载器，您应该将Document Class代码移动到FLA文件的第2帧（当然不包含包和类构造函数），然后删除Document Class。作为项目属性的文件。在第一帧中，您应该放置这样的代码：

stop(); // stops the timeline at preloader frame
this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
function onProgress(e:ProgressEvent):void {
    var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
    //additional code to update preloader graphics
    //..
    if (percent == 100) onLoaded();
}
function onLoaded() {
   this.loaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
   nextFrame();
}

加载swf后，它会前进到下一帧并执行原始应用程序初始化代码。如果您以大多数资产（图像等）在Flash IDE库中并且未在第一帧上加载（您可以在每个库项目的属性中检查）的方式组织项目，这种方法很有效。

选项2. Flash IDE，两个swf文件

另一个选项，正如另一个评论者所建议的那样，是保持你的应用程序swf原样，并创建另一个轻量级swf，它将加载第一个。第一帧中preloader.swf的代码：

var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
loader.load(new URLRequest("path/to/application.swf"));

function onProgress(e:ProgressEvent):void
{
   var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
   //additional code to update preloader graphics
   //..
   if (percent == 100) onLoaded();
}
function onLoaded():void
{
   loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
   var application:DisplayObject = loader.content;
   addChild(application);
}

当您尝试从stage等访问Document Class constructor时，此方法存在其他问题，但在大多数情况下，这应该可以胜任。

选项3.不同的IDE，我的建议： FlashDevelop

如果您尝试使用FlashDevelop，Flash Builder或任何其他IDE编译我最初发布的代码，它应该可以正常工作。

原帖：

这是嵌入式预加载器的基本设置。您的Document Class应如下所示：

package {

  import flash.display.Sprite;

  [Frame(factoryClass='Preloader')] //class name of your preloader

  public class Main extends Sprite {

     public function Main() {
        //init
     }
  }
}

预加载器类：

package {

   import flash.display.DisplayObject;
   import flash.display.MovieClip;
   import flash.events.ProgressEvent;
   import flash.utils.getDefinitionByName;

  public class Preloader extends MovieClip {

     public function Preloader()
     {
        //add preloader graphics 

        //check loading progress
        this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgress);
     }
     private function onProgress(e:ProgressEvent):void 
     {
        var percent:Number = Math.round(e.bytesLoaded / e.bytesTotal * 100);
        if (percent == 100)
        {
          this.loaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgress);
          onLoaded();
        }
     }
     private function onLoaded():void
     {
       nextFrame(); //go to next frame
       var App:Class = getDefinitionByName("Main") as Class; //class of your app
       addChild(new App() as DisplayObject);
     }
  }
}

Answer 2

我建议使用“轻量级swf装载重型swf”路线，因为它是我见过的最有效率的路线。那里有很多臃肿的教程，但对我来说，我喜欢这个教程http://doogog.com/actionscript-3-external-preloader.html这是直截了当的。

Answer 3

以下是有关如何创建嵌入式as3预加载器的文章 http://www.kirupa.com/forum/showthread.php?351689-actionscript-preloader-in-flash-develop

Answer 4

您还可以在应用程序启动前和加载应用程序文件时使用Greensock等第三方库进行预加载。

我个人使用Greensock并推荐它。它使用loaderInfo类解决了一些错误。

http://www.greensock.com/loadermax/

Answer 5

[Frame（factoryClass ='Preloader'）]不再适用于新的ASC 2.0编译器。相反，预加载器成为您的文档类，您需要添加一个Additional Compiler Argument来告诉flash在第二帧中包含您的主类（不要在预加载器中引用它）：

-frame = NameDoesntMatter，主

Does ASC 2.0 recognize [Frame] metadata tags (ex: for Preloader factoryClass)?

ASC2.0 and Frame metatag

如何在AS3中创建Preloader

5 个答案: