Question

我正在尝试从oracle表中获取一个名为“sys.all_objects”的查询到一个字符串变量，所以我可以把它作为输入“dbms_obfuscation_toolkit.DESEncrypt”，然后加密的字符串将进入“utl_file”，这样我就可以将它写入一个txt文件。

当我尝试使用此代码查询时出现问题;

DECLARE
TYPE name_array is array(50) OF varchar2(100);
var_input  name_array; 

BEGIN
SELECT owner
  INTO var_input
  FROM sys.all_objects;

  FOR i IN var_input.FIRST .. var_input.LAST
    LOOP
        dbms_output.put_line(var_input(i));
    END LOOP;
END;

，错误是;

ORA-06550: line 7, column 12:
PLS-00642: local collection types not allowed in SQL statements

关于解决这个问题的任何想法？

对于想要查看完整代码的人;

CREATE OR REPLACE DIRECTORY data AS 'd:\folder';
GRANT read, write ON DIRECTORY data TO PUBLIC;

DECLARE
var_input  varchar2(64) := 'Rndminpt';
var_key    varchar2(16) := 'Anahtar1'; 
var_enc    varchar2(1024);
var_dec    varchar2(1024);
var_file   utl_file.file_type;

BEGIN

-- (query part)

    dbms_obfuscation_toolkit.DESEncrypt(
        input_string     =>  var_input,
        key_string       =>  var_key,
        encrypted_string =>  var_enc);
    dbms_output.put_line('Encrypted...');

var_file := utl_file.fopen('DATA','textfile.txt','W');            
    utl_file.put_line(var_file,var_enc);
    utl_file.fclose(var_file);        
dbms_output.put_line('Writen in to text... ');      
END;

Answer 1

尝试使用游标和BULK COLLECT代替： http://www.dba-oracle.com/t_oracle_bulk_collect.htm

应该是这样的：

DECLARE
TYPE name_array is array(50) OF varchar2(100);
var_input  name_array; 


cursor c1 is
SELECT owner
  FROM sys.all_objects;

BEGIN
    open c1;
    fetch c1 bulk collect into var_input;
    close c1;

  FOR i IN var_input.FIRST .. var_input.LAST
    LOOP
        dbms_output.put_line(var_input(i));
    END LOOP;
END;

没有检查代码

Answer 2

这只是对A.B.Cade答案的澄清。光标与问题无关。

的根本原因

PLS-00642: local collection types not allowed in SQL statements

是sql into只能用于PL / SQL变量或记录，但不能用于PL / SQL集合。

使用PL / SQL集合时，必须使用select bulk collect into。

（是的 - 我同意错误信息可能更具描述性。）

另见：

SELECT INTO Statement

<强>实施例

以下匿名块使用PLS-00642进行编译，因为select into无法与集合一起使用：

declare
  type dual_list_t is table of dual%rowtype;
  v_duals dual_list_t;
begin
  select *
    into v_duals
    from dual
  connect by level <= 2
  ;
end;
/

以下匿名块编译正常：

declare
  type dual_list_t is table of dual%rowtype;
  v_duals dual_list_t;
begin
  select *
    bulk collect into v_duals
    from dual
  connect by level <= 2
  ;
end;
/

Answer 3

只需使用下面给定的块即可成功执行：

DECLARE
TYPE name_array is array(50) OF varchar2(100);
var_input  name_array; 

BEGIN
SELECT owner Bulk Collect
  INTO var_input
  FROM sys.all_objects;

  FOR i IN var_input.FIRST .. var_input.LAST
    LOOP
        dbms_output.put_line(var_input(i));
    END LOOP;
END;

PL / SQL ORA-06550中的“本地集合类型不允许”错误

3 个答案: