Question

我正在尝试使用pdfsharp library将多个图像转换为pdf。

我能够转换单张图片并且效果非常好。

在将bulk images转换为single pdf时，我遇到的问题是它需要所有图片并转换它们但转换后如果我检查它只显示最后一张图片，因为它没有附加到现有图像并覆盖以前的图像。

那我该如何纠正呢？

任何帮助将不胜感激，因为我第一次使用pdf库并指出我如果我有任何错误。我会很高兴知道更多关于这一点我不会感到如果你指出我我做错了。

这是我的代码：

 Private Sub btnAddFolder_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAddFolder.Click
            If Me.FolderBrowserDialog1.ShowDialog = Windows.Forms.DialogResult.OK Then

            Dim f As New DirectoryInfo(Me.FolderBrowserDialog1.SelectedPath)
            Dim fso As New System.Object
            For Each file As FileInfo In f.GetFiles
                Select Case file.Extension.ToLower
                    Case ".jpg", ".bmp", ".gif", ".png"
                        Me.ThumbControl1.BackgroundImage = Nothing
                        Me.CheckedListBox1.Items.Add(file.FullName, CheckState.Checked)
                        Me.ThumbControl1.AddThumbnail(file.FullName)
                        Me.ThumbControl1.BackgroundImage = Nothing
                        Me.CheckedListBox1.SelectedIndex = 0
                End Select
            Next
            End If
    End Sub

后台工作人员：

 Private Sub bw_DoWork(ByVal sender As Object, ByVal e As DoWorkEventArgs) Handles bw.DoWork
        For pix As Integer = 0 To CheckedListBox1.CheckedItems.Count - 1
            Try
                Dim source As String = CheckedListBox1.Items(pix).ToString()
                Dim destinaton As String = (TryCast(e.Argument, String()))(1)

                Dim doc As New PdfDocument()
                doc.Pages.Add(New PdfPage())
                Dim xgr As XGraphics = XGraphics.FromPdfPage(doc.Pages(0))
                Dim img As XImage = XImage.FromFile(source)

                xgr.DrawImage(img, 0, 0)
                doc.Save(destinaton)
                doc.Close()
                success = True
            Catch ex As Exception
                MessageBox.Show(ex.Message, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
            End Try
        Next
    End Sub

转换按钮：

  Private Sub btnConvert_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnConvert.Click
         bw.RunWorkerAsync(New String(1) {srcFile, destFile})
  End sub

保存Pdf：

Private Sub btnSelectDest_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles btnSelectDest.Click
        sfdDestFile.Filter = "PDF Files(*.pdf)|*.pdf"
        If sfdDestFile.ShowDialog() <> System.Windows.Forms.DialogResult.OK Then
            Return
        End If
        destFile = sfdDestFile.FileName
 End Sub

Answer 1

问题是您是在每次循环中创建一个新的PDF文档。你需要在循环之外移动它。此外，您引用的是第0页，而不是第pix页。以下是我将如何解决它：

Private Sub bw_DoWork(ByVal sender As Object, ByVal e As DoWorkEventArgs) Handles bw.DoWork
    Dim doc As New PdfDocument()

    For pix As Integer = 0 To CheckedListBox1.CheckedItems.Count - 1
        Try
            Dim source As String = CheckedListBox1.Items(pix).ToString()
            Dim oPage As New PDFPage()

            doc.Pages.Add(oPage)
            Dim xgr As XGraphics = XGraphics.FromPdfPage(oPage)
            Dim img As XImage = XImage.FromFile(source)

            xgr.DrawImage(img, 0, 0)
            success = True
        Catch ex As Exception
            MessageBox.Show(ex.Message, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
        End Try
    Next

    Dim destinaton As String = (TryCast(e.Argument, String()))(1)
    doc.Save(destinaton)
    doc.Close()
End Sub

使用pdfsharp将多个图像转换为pdf

1 个答案: