Question

我似乎无处可去。在网上搜索脚本等等。任何人都有一个脚本，您可以在Windows环境中编辑现成的pre-commit.tmpl，该环境需要输入x字符才能在Tortoise Subversion中提交注释全局，以便团队中的所有成员都需要，而这个要求是从SVN服务器推送到客户端的？

我不知道脚本语言，如果没有花时间在接下来的3个小时内找出脚本，这应该是非常简单的事情。

Answer 1

这是一个要求有评论的.bat文件。它会检查评论中是否存在至少一个字符。

 @echo off  
 :: Stops commits that have empty log messages.        
 @echo off  

 setlocal  

 rem Subversion sends through the path to the repository and transaction id  
 set REPOS=%1  
 set TXN=%2           

 svnlook log %REPOS% -t %TXN% | findstr . > nul  
 if %errorlevel% gtr 0 (goto err) else exit 0  

 :err  
 echo. 1>&2  
 echo Your commit has been blocked because you didn't enter a comment. 1>&2  
 echo Write a log message describing the changes made and try again. 1>&2
 echo Thanks 1>&2
 exit 1

此文件位于存储库的/ hooks文件夹中，名为pre-commit.bat。如果您需要最少量的字符，则要修改的行是

svnlook log %REPOS% -t %TXN% | findstr . > nul

因此，如果你想要至少10个字符，你需要有10个字符而不是只有一个

svnlook log %REPOS% -t %TXN% | findstr .......... > nul

更多advanced options for the findstr命令可以让你进行更高级的检查（某些字符集等）

Answer 2

我使用SubversionNotify，它可能比您需要的更多，但设置起来非常简单。

Answer 3

试试这个：

rem Make sure that the log message contains some text.
set REPOS=%1
set TXN=%2

"C:\Program Files\Subversion\bin\SVNlook.exe" log -t %TXN% %REPOS% | FindStr [a-zA-Z0-9]  
IF %ERRORLEVEL% EQU 0 GOTO OK  
echo Your commit has been blocked because you didn't provide a log message 1>&2  
echo Please write a log message describing the purpose of your changes and 1>&2  
echo then try committing again. -- Thank you 1>&2   
exit 1  

:OK  
rem -------------------------------------------------------------  
rem Check if comment is in list of reserved words to not be used..  
rem -------------------------------------------------------------  

"C:\Program Files\Subversion\bin\SVNlook.exe" log -t %TXN% %REPOS% >comment  
setlocal enabledelayedexpansion  
Set SEPARATOR=  
set COMMENT=  
for /f "delims=" %%a in (comment) do (      
    set currentline=%%a  
    set COMMENT=!COMMENT!%SEPARATOR%!currentline!  
)  

FIND "%COMMENT%" "C:\Program Files\Subversion\excludedwords.txt">Null  
If %ERRORLEVEL% EQU 1 goto OK2  

:Fail  
echo Your commit has been blocked because the single word comment you provided is not allowed 1>&2  
echo Line is -%COMMENT%- 1>&2  
echo Please write a proper log message describing the purpose of your changes and 1>&2  
echo then try committing again. -- Thank you 1>&2   
exit 1  


:OK2  
rem -------------------------------------------------------------  
rem Check number of words on the line if = 2 then reject comment  
rem -------------------------------------------------------------  
Set VAR1=%COMMENT%  
Set count=0  
For %%j in (%VAR1%) Do Set /A count+=1  
IF %count% EQU 2 goto Fail2  
goto OK3  

:Fail2  
echo Your commit has been blocked because not enough detail supplied 1>&2  
echo Please write a longer log message describing the purpose of your changes and 1>&2  
echo then try committing again. -- Thank you 1>&2   
exit 1  

:OK3  
rem -------------------------------------------------------------  
rem Check that the author of this commit has the rights to perform  
rem -------------------------------------------------------------  
rem the commit on the files and directories being modified.  
rem commit-access-control.pl "$REPOS" "$TXN" commit-access-control.cfg || exit 1  

rem All checks passed, so allow the commit.  
exit 0

Answer 4

我有pre-commit hook可以完全按照您的意愿行事。还有更多。

您可以指定提交评论的最小长度。
您可以将提交评论与regular expression进行匹配。您不仅可以指定长度，还可以指定某些参数。例如，提交注释是否包含缺陷跟踪系统使用的错误编号，因此您可以追溯到特定缺陷的更改？

它还允许您执行以下操作：

针对特定文件或目录设置各种提交权限：
- 读写：用户可以签出并提交这些项目。
- 只读：用户可以签出此项，但无法提交更改。
- 仅限添加：用户可以通过svn cp添加目录，但不提交任何更改。这非常适合允许您制作标记的/tags目录，但不能修改标记。
- no-delete ：用户可以提交更改并添加新文件，但不能删除这些文件。
- no-add ：用户只能提交更改，而不能在提交中添加或删除文件。

并且，它还允许您这样做：

通过globbing，
要求某些文件或目录将特定属性设置为特定值。对于确保Unix shell脚本，Unix Makefile和Windows Batch文件具有正确的行结尾或设置svn:ignore之类的内容非常有用，因此用户不会意外地提交他们不应提交的文件。
要求使用特定值设置某些修订属性。这是检查提交消息的方法，但是说svn:log必须与某些正则表达式匹配。

这个预提交脚本是用Perl编写的。默认情况下，Perl附带Unix，Mac和Linux服务器。不幸的是，它不包含在Windows计算机上。幸运的是，有几个开源，免费且易于安装的PC Perl软件包，例如ActivePerl和Strawberry Perl

Answer 5

在Windows上，可以使用VisualSVN Server随附的VisualSVNServerHooks.exe check-logmessage预提交钩子，该钩子位于%VISUALSVN_SERVER%bin目录中。这个简单的工具将帮助您定义日志消息中允许的最小字符数。

有关说明，请参见文章KB140: Validating commit log messages in VisualSVN Server。

用于注释长度Subversion的Windows预提交钩子

5 个答案: