Question

当调整窗口大小时，我想在调整大小时处理OnResize事件，因为更新图形需要几秒钟。这很棘手，因为调整窗口大小会产生大量的调整大小事件。由于更新窗口需要一段时间，我不希望在每个事件上更新窗口。我试图检测一个鼠标，将其标记为完成调整大小的事件但是从未检测到鼠标。

TLama有一个nice solution但是唉，这是VCL，我需要Firemonkey。有关FMX的任何建议吗？

Answer 1

类似Debounce() or Throttle() function in Underscore.js的内容怎么样？这两个函数都提供了限制程序执行顺序的方法。

Answer 2

以下是在Windows上使用FMX处理它的方法，您需要将表单更改为从TResizeForm继承并分配OnResizeEnd属性。不太干净，因为它取决于FMX内部，但应该工作。

unit UResizeForm;

interface

uses
  Winapi.Windows,
  System.SysUtils, System.Classes,
  FMX.Types, FMX.Forms, FMX.Platform.Win;

type
  TResizeForm = class(TForm)
  strict private
    class var FHook: HHook;
  strict private
    FOnResizeEnd: TNotifyEvent;
  public
    property OnResizeEnd: TNotifyEvent read FOnResizeEnd write FOnResizeEnd;
    class constructor Create;
    class destructor Destroy;
  end;

implementation

uses Winapi.Messages;

var
  WindowAtom: TAtom;

function Hook(code: Integer; wparam: WPARAM; lparam: LPARAM): LRESULT stdcall;
var
  cwp: PCWPSTRUCT;
  Form: TForm;
  ResizeForm: TResizeForm;
begin
  try
    cwp := PCWPSTRUCT(lparam);
    if cwp.message = WM_EXITSIZEMOVE then
    begin
      if WindowAtom <> 0 then
      begin
        Form := TForm(GetProp(cwp.hwnd, MakeIntAtom(WindowAtom)));
        if Form is TResizeForm then
        begin
          ResizeForm := Form as TResizeForm;
          if Assigned(ResizeForm.OnResizeEnd) then
          begin
            ResizeForm.OnResizeEnd(ResizeForm);
          end;
        end;
      end;
    end;
  except
    // eat exception
  end;
  Result := CallNextHookEx(0, code, wparam, lparam);
end;

class constructor TResizeForm.Create;
var
  WindowAtomString: string;
begin
  WindowAtomString := Format('FIREMONKEY%.8X', [GetCurrentProcessID]);
  WindowAtom := GlobalFindAtom(PChar(WindowAtomString));
  FHook := SetWindowsHookEx(WH_CALLWNDPROC, Hook, 0, GetCurrentThreadId);
end;

class destructor TResizeForm.Destroy;
begin
  UnhookWindowsHookEx(FHook);
end;

end.

Answer 3

作为一种解决方法，在表单中添加TTimer，将其初始状态设置为disabled，将Interval属性设置为100 ms。要最大程度地减少应用程序对OnResize事件做出反应的次数，请使用以下代码：

procedure TForm1.FormResize(Sender: TObject);
begin
    with ResizeTimer do
    begin
        Enabled := false;
        Enabled := true;
    end;
end;

procedure TForm1.ResizeTimerTimer(Sender: TObject);
begin
    ResizeTimer.Enabled := false;

    // Do stuff after resize
end;

用户不应注意到最小延迟。

在FMX中处理OnResize的最佳方法是什么？

3 个答案: