Question

是否有算法引导给定数量的三值逻辑值的所有可能组合？

例如，F(2)应返回此列表：

t t
t u
t f
u t
u u
u f
f t
f u
f f

该函数看起来像这样（在Haskell中）：

data Tril = FALSE | NULL | TRUE

all :: Int -> [[Tril]]
all amount = ???

all1 :: [Tril]
all1 = join (all 1)

all2 :: [(Tril, Tril)]
all2 = map (\[f, s] -> (f, s)) (all 2)

all3 :: [(Tril, Tril, Tril)]
all3 = map (\[f, s, t] -> (f, s, t)) (all 3)

Answer 1

您可以非常简单地将其作为列表理解：

all2 = [ (v1, v2) | v1 <- [FALSE, TRUE, NULL], v2 <- [FALSE, TRUE, NULL] ]

你可以把它写成monadic do-block：

all2 = do
  v1 <- [FALSE, TRUE, NULL]
  v2 <- [FALSE, TRUE, NULL]
  return (v1, v2)

这让我们知道如何编写可变大小的一个：

all 0 = [[]] -- Note: Empty list with one empty item.
all n = do
  v  <- [FALSE, TRUE, NULL]
  vs <- all (n-1)
  return (v:vs)

事实证明 - 这有点令人费解 - 这是replicateM函数的净效应。它需要一个monadic动作，N次，并将结果收集在一起。

all n = replicateM n [FALSE, TRUE, NULL]

Answer 2

replicateM正是如此：

> import Control.Monad
> replicateM 2 [1,2,3]
[[1,1],[1,2],[1,3],[2,1],[2,2],[2,3],[3,1],[3,2],[3,3]]

因此，

all :: Int -> [[Tril]]
all amount = replicateM amount [FALSE,NULL,TRUE]

我建议选择其他名称，因为all已经Prelude.all采取了{{1}}。

三值逻辑值的所有可能组合

2 个答案: